[arch-commits] Commit in python-requestsexceptions/repos (2 files)

[Felix Yan]

    Date: Friday, February 26, 2016 @ 06:56:17
  Author: fyan
Revision: 163464

archrelease: copy trunk to community-any

Added:
  python-requestsexceptions/repos/community-any/
  python-requestsexceptions/repos/community-any/PKGBUILD
    (from rev 163463, python-requestsexceptions/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: python-requestsexceptions/repos/community-any/PKGBUILD (from rev 163463, python-requestsexceptions/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2016-02-26 05:56:17 UTC (rev 163464)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+
+pkgbase=python-requestsexceptions
+pkgname=(python-requestsexceptions python2-requestsexceptions)
+pkgver=1.1.3
+pkgrel=1
+pkgdesc="Import exceptions from potentially bundled packages in requests."
+arch=('any')
+url="https://github.com/openstack-infra/requestsexceptions"
+license=('Apache')
+makedepends=('git' 'python-setuptools' 'python2-setuptools' 'python-pbr' 'python2-pbr'
+             'python-requests' 'python2-requests')
+source=("git+https://github.com/openstack-infra/requestsexceptions.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a requestsexceptions{,-py2}
+}
+
+build() {
+  cd "$srcdir"/requestsexceptions
+  python setup.py build
+
+  cd "$srcdir"/requestsexceptions-py2
+  python2 setup.py build
+}
+
+package_python-requestsexceptions() {
+  depends=('python-pbr' 'python-requests')
+
+  cd "$srcdir"/requestsexceptions
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-requestsexceptions() {
+  depends=('python2-pbr' 'python2-requests')
+
+  cd "$srcdir"/requestsexceptions-py2
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et: