[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, February 26, 2016 @ 09:52:55
  Author: fyan
Revision: 163488

addpkg: python-warlock 1.2.0-1

Added:
  python-warlock/
  python-warlock/repos/
  python-warlock/trunk/
  python-warlock/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-warlock/trunk/PKGBUILD
===================================================================
--- python-warlock/trunk/PKGBUILD	                        (rev 0)
+++ python-warlock/trunk/PKGBUILD	2016-02-26 08:52:55 UTC (rev 163488)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-warlock
+pkgname=('python-warlock' 'python2-warlock')
+pkgver=1.2.0
+pkgrel=1
+pkgdesc="Python object model built on JSON schema and JSON patch."
+arch=('any')
+license=('Apache')
+url="https://github.com/bcwaldon/warlock"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-jsonschema' 'python2-jsonschema'
+             'python-jsonpatch' 'python2-jsonpatch' 'python-six' 'python2-six' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("git+https://github.com/bcwaldon/warlock.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a warlock{,-py2}
+}
+
+build() {
+  cd "$srcdir"/warlock
+  python setup.py build
+
+  cd "$srcdir"/warlock-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/warlock
+  python setup.py ptr
+
+  cd "$srcdir"/warlock-py2
+  python2 setup.py ptr
+}
+
+package_python-warlock() {
+  depends=('python-jsonschema' 'python-jsonpatch' 'python-six')
+
+  cd warlock
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-warlock() {
+  depends=('python2-jsonschema' 'python2-jsonpatch' 'python2-six')
+
+  cd warlock-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}


Property changes on: python-warlock/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property