[arch-commits] Commit in (4 files)
Felix Yan
fyan at archlinux.org
Fri Feb 26 10:00:12 UTC 2016
Date: Friday, February 26, 2016 @ 11:00:11
Author: fyan
Revision: 163494
addpkg: python-keystoneclient 2.2.0-1
Added:
python-keystoneclient/
python-keystoneclient/repos/
python-keystoneclient/trunk/
python-keystoneclient/trunk/PKGBUILD
----------+
PKGBUILD | 66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 66 insertions(+)
Added: python-keystoneclient/trunk/PKGBUILD
===================================================================
--- python-keystoneclient/trunk/PKGBUILD (rev 0)
+++ python-keystoneclient/trunk/PKGBUILD 2016-02-26 10:00:11 UTC (rev 163494)
@@ -0,0 +1,66 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-keystoneclient
+pkgname=(python-keystoneclient python2-keystoneclient)
+pkgver=2.2.0
+pkgrel=1
+pkgdesc="Client Library for OpenStack Identity"
+arch=('any')
+url="http://docs.openstack.org/developer/python-keystoneclient"
+license=('Apache')
+makedepends=('git' 'python-setuptools' 'python2-setuptools' 'python-pbr' 'python2-pbr'
+ 'python-iso8601' 'python2-iso8601' 'python-prettytable' 'python2-prettytable'
+ 'python-debtcollector' 'python2-debtcollector' 'python-keystoneauth1'
+ 'python2-keystoneauth1' 'python-positional' 'python2-positional' 'python-oslo-utils'
+ 'python2-oslo-utils' 'python-oslo-i18n' 'python2-oslo-i18n'
+ 'python-oslo-serialization' 'python2-oslo-serialization' 'python-oslo-config'
+ 'python2-oslo-config' 'python-requests' 'python2-requests' 'python-stevedore'
+ 'python2-stevedore')
+checkdepends=('python-oslotest' 'python2-oslotest' 'python-testresources' 'python2-testresources'
+ 'python-requests-mock' 'python2-requests-mock' 'pep8' 'python2-pep8' 'python-lxml'
+ 'python2-lxml')
+source=("git+https://git.openstack.org/openstack/python-keystoneclient#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+ cp -a python-keystoneclient{,-py2}
+}
+
+build() {
+ cd "$srcdir"/python-keystoneclient
+ python setup.py build
+
+ cd "$srcdir"/python-keystoneclient-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/python-keystoneclient
+ python setup.py testr
+
+ cd "$srcdir"/python-keystoneclient-py2
+ PYTHON=python2 python2 setup.py testr
+}
+
+package_python-keystoneclient() {
+ depends=('python-six' 'python-pbr' 'python-iso8601' 'python-prettytable' 'python-debtcollector'
+ 'python-keystoneauth1' 'python-positional' 'python-oslo-utils' 'python-oslo-i18n'
+ 'python-oslo-serialization' 'python-oslo-config' 'python-requests' 'python-stevedore')
+
+ cd "$srcdir"/python-keystoneclient
+ python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-keystoneclient() {
+ depends=('python2-six' 'python2-pbr' 'python2-iso8601' 'python2-prettytable' 'python2-debtcollector'
+ 'python2-keystoneauth1' 'python2-positional' 'python2-oslo-utils' 'python2-oslo-i18n'
+ 'python2-oslo-serialization' 'python2-oslo-config' 'python2-requests' 'python2-stevedore')
+
+ cd "$srcdir"/python-keystoneclient-py2
+ python2 setup.py install --root="$pkgdir/" --optimize=1
+
+ mv "$pkgdir"/usr/bin/keystone{,2}
+}
+
+# vim:set ts=2 sw=2 et:
Property changes on: python-keystoneclient/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list