[arch-commits] Commit in (binwalk binwalk/repos binwalk/trunk binwalk/trunk/PKGBUILD)

[Levente Polyak]

    Date: Saturday, January 2, 2016 @ 22:55:18
  Author: anthraxx
Revision: 155199

addpkg: binwalk 2.1.1-1

Added:
  binwalk/
  binwalk/repos/
  binwalk/trunk/
  binwalk/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: binwalk/trunk/PKGBUILD
===================================================================
--- binwalk/trunk/PKGBUILD	                        (rev 0)
+++ binwalk/trunk/PKGBUILD	2016-01-02 21:55:18 UTC (rev 155199)
@@ -0,0 +1,49 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Peter Wu <peter at lekensteyn.nl>
+# Contributor: Miguel Revilla <yo at miguelrevilla.com>
+# Contributor: s1gma <s1gma at mindslicer.com>
+
+pkgname=binwalk
+pkgver=2.1.1
+pkgrel=1
+pkgdesc="A tool for searching a given binary image for embedded files"
+url="http://binwalk.org"
+arch=('any')
+license=('MIT')
+depends=('python')
+optdepends=(
+  'python-pyqtgraph: graph and visualization support'
+  'python-opengl: binviz module support'
+  'python-capstone: disassembly support'
+  'arj: ARJ decompression support'
+  'cabextract: CAB archive support'
+  'cpio: CPIO archvie support'
+  'gzip: GZIP decompression support'
+  'lha: LHA decompression support'
+  'mtd-utils: JFFS filesystem support'
+  'p7zip: ZIP, LZMA and ISO decompression support'
+  'squashfs-tools: squashfs support'
+  'tar: TAR archive support'
+  'bzip2: BZIP2 archive support'
+  'unrar: RAR decompression support'
+  'xz: XZ decompression support'
+  'firmware-mod-kit: cramfs support'
+  'lhasa: LHA support'
+  'sleuthkit: forensic analysis support'
+)
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/devttys0/${pkgname}/archive/v${pkgver}.tar.gz)
+sha512sums=('373e276a4d6ec845952f1091f85f953d3b0d52d561d9b74a54000ebdef85d13cafc997a4f8f76f25842db8b76fdcd1e602d4d81792a3ea01c9dea6c6ed5c2168')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  python setup.py build
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  python setup.py install -O1 --prefix="${pkgdir}/usr"
+  install -Dm 644 *.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+# vim: ts=2 sw=2 et: