[arch-commits] Commit in (4 files)

Felix Yan fyan at archlinux.org
Thu Jan 7 03:01:48 UTC 2016


    Date: Thursday, January 7, 2016 @ 04:01:47
  Author: fyan
Revision: 155616

addpkg: python-pypandoc 1.1.2-1

Added:
  python-pypandoc/
  python-pypandoc/repos/
  python-pypandoc/trunk/
  python-pypandoc/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: python-pypandoc/trunk/PKGBUILD
===================================================================
--- python-pypandoc/trunk/PKGBUILD	                        (rev 0)
+++ python-pypandoc/trunk/PKGBUILD	2016-01-07 03:01:47 UTC (rev 155616)
@@ -0,0 +1,51 @@
+# $Id: PKGBUILD 141139 2015-09-20 03:14:59Z fyan $
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-pypandoc
+pkgname=('python-pypandoc' 'python2-pypandoc')
+pkgver=1.1.2
+pkgrel=1
+pkgdesc="Thin wrapper for pandoc"
+arch=('any')
+license=('MIT')
+url="https://github.com/bebraw/pypandoc"
+makedepends=('python-setuptools' 'python2-setuptools' 'pandoc' 'git')
+checkdepends=('texlive-core' 'pandoc-citeproc')
+source=("git+https://github.com/bebraw/pypandoc.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a pypandoc{,-py2}
+}
+
+build() {
+  cd "$srcdir/pypandoc"
+  python setup.py build
+
+  cd "$srcdir/pypandoc-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/pypandoc"
+  python setup.py test
+
+  cd "$srcdir/pypandoc-py2"
+  python2 setup.py test
+}
+
+package_python-pypandoc() {
+  depends=('python' 'pandoc')
+
+  cd pypandoc
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-pypandoc() {
+  depends=('python2' 'pandoc')
+
+  cd pypandoc-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list