[arch-commits] Commit in strip-nondeterminism/repos (2 files)

[Levente Polyak]

    Date: Monday, January 18, 2016 @ 01:56:50
  Author: anthraxx
Revision: 157277

archrelease: copy trunk to community-any

Added:
  strip-nondeterminism/repos/community-any/
  strip-nondeterminism/repos/community-any/PKGBUILD
    (from rev 157276, strip-nondeterminism/trunk/PKGBUILD)

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Copied: strip-nondeterminism/repos/community-any/PKGBUILD (from rev 157276, strip-nondeterminism/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2016-01-18 00:56:50 UTC (rev 157277)
@@ -0,0 +1,36 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=strip-nondeterminism
+pkgver=0.014
+pkgrel=1
+pkgdesc='Tool for stripping bits of non-deterministic information from files'
+url='https://anonscm.debian.org/git/reproducible/strip-nondeterminism.git'
+arch=('any')
+license=('GPL3')
+depends=("perl" 'perl-archive-zip')
+makedepends=('git')
+options=('!emptydirs')
+source=(${pkgname}::"git+https://anonscm.debian.org/git/reproducible/strip-nondeterminism.git#tag=${pkgver}")
+sha512sums=('SKIP')
+validpgpkeys=('C2FE4BD271C139B86C533E461E953E27D4311E58'  # Chris Lamb <lamby at debian.org>
+              'EF5D84C1838F2EB6D8968C0410378EFC2080080C') # Andrew Ayer <agwa at andrewayer.name>
+
+prepare() {
+  cd ${pkgname}
+  git tag --verify ${pkgver}
+  sed -r 's|bin/dh_strip_nondeterminism ||g' -i Makefile.PL
+}
+
+build() {
+  cd ${pkgname}
+  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
+  make
+}
+
+package() {
+  cd ${pkgname}
+  make DESTDIR="${pkgdir}" install
+  install -Dm 644 README "${pkgdir}/usr/share/doc/${pkgname}/README"
+}
+
+# vim: ts=2 sw=2 et: