[arch-commits] Commit in python-packaging/repos (testing-any testing-any/PKGBUILD)

[Felix Yan]

    Date: Wednesday, January 20, 2016 @ 02:10:51
  Author: fyan
Revision: 258425

archrelease: copy trunk to testing-any

Added:
  python-packaging/repos/testing-any/
  python-packaging/repos/testing-any/PKGBUILD
    (from rev 258424, python-packaging/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: python-packaging/repos/testing-any/PKGBUILD (from rev 258424, python-packaging/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2016-01-20 01:10:51 UTC (rev 258425)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-packaging
+pkgname=(python-packaging python2-packaging)
+_pkgname=packaging
+pkgver=16.0
+_commit=fd6c1d301a5162d4c78620444c55bd56aa2670a0
+pkgrel=1
+pkgdesc="Core utilities for Python packages"
+arch=('any')
+url="https://github.com/pypa/packaging"
+license=('Apache')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pyparsing' 'python2-pyparsing' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-pretend' 'python2-pretend' 'python-coverage' 'python2-coverage')
+source=("git+https://github.com/pypa/packaging.git#commit=$_commit")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a $_pkgname{,-py2}
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}"
+  python setup.py build
+
+  cd "${srcdir}/${_pkgname}-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "${srcdir}/${_pkgname}"
+  python setup.py ptr
+
+  cd "${srcdir}/${_pkgname}-py2"
+  python2 setup.py ptr
+}
+
+package_python-packaging() {
+  depends=('python-pyparsing')
+
+  cd "${srcdir}/${_pkgname}"
+  python setup.py install --root "$pkgdir"
+}
+
+package_python2-packaging() {
+  depends=('python2-pyparsing')
+
+  cd "${srcdir}/${_pkgname}-py2"
+  python2 setup.py install --root "$pkgdir"
+}