[arch-commits] Commit in python-keyring/repos (2 files)
Felix Yan
fyan at archlinux.org
Sat Jan 23 02:01:07 UTC 2016
Date: Saturday, January 23, 2016 @ 03:01:07
Author: fyan
Revision: 158639
archrelease: copy trunk to community-testing-any
Added:
python-keyring/repos/community-testing-any/
python-keyring/repos/community-testing-any/PKGBUILD
(from rev 158638, python-keyring/trunk/PKGBUILD)
----------+
PKGBUILD | 72 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 72 insertions(+)
Copied: python-keyring/repos/community-testing-any/PKGBUILD (from rev 158638, python-keyring/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD (rev 0)
+++ community-testing-any/PKGBUILD 2016-01-23 02:01:07 UTC (rev 158639)
@@ -0,0 +1,72 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Johannes Dewender arch at JonnyJD dot net
+# Contributor: Ivan Sichmann Freitas <ivansichfreitas at gmail.com>
+# Contributor: Brice Maron <brice at bmaron.net>
+# Contributor: Nuno Araujo <nuno.araujo at russo79.com>
+# Contributor: Steven Allen <steven {at} stebalien {dot} com>
+
+pkgbase=python-keyring
+pkgname=('python-keyring' 'python2-keyring')
+pkgver=8.0
+pkgrel=1
+pkgdesc="Store and access your passwords safely."
+arch=('any')
+url="http://pypi.python.org/pypi/keyring"
+license=('PSF' 'MIT')
+source=("http://pypi.python.org/packages/source/k/keyring/keyring-$pkgver.tar.gz")
+makedepends=('python-setuptools_scm' 'python2-setuptools_scm')
+checkdepends=('python-pytest' 'python2-pytest' 'python-mock' 'python2-mock' 'python-crypto' 'python2-crypto'
+ 'python-secretstorage' 'python2-secretstorage' 'python-gobject' 'python2-gobject' 'libgnome-keyring'
+ 'python2-gdata' 'python-fs' 'python2-fs' 'xorg-server-xvfb')
+md5sums=('c0b86e5851a304630398f12279a5ed57')
+
+prepare() {
+ cp -a keyring-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir/keyring-$pkgver"
+ python setup.py build
+
+ cd "$srcdir/keyring-$pkgver-py2"
+ python2 setup.py build
+}
+
+check() {
+ # Not using ptr because we are not packaging keyczar
+
+ cd "$srcdir/keyring-$pkgver"
+ xvfb-run py.test
+
+ cd "$srcdir/keyring-$pkgver-py2"
+ xvfb-run py.test2
+}
+
+package_python-keyring() {
+ depends=('python-setuptools')
+ optdepends=('libgnome-keyring: Gnome integration'
+ 'python-gobject: Gnome integration'
+ 'kdebindings-python: Kde integration'
+ 'python-crypto: CLI keyring'
+ 'python-secretstorage: SecretService DBus API (GNOME/KDE)')
+
+ cd "$srcdir/keyring-$pkgver"
+ python setup.py install --root=$pkgdir --optimize=1
+}
+
+package_python2-keyring() {
+ depends=('python2-setuptools')
+ optdepends=('libgnome-keyring: Gnome integration'
+ 'python2-gobject: Gnome integration'
+ 'kdebindings-python2: Kde integration'
+ 'python2-crypto: CLI keyring'
+ 'python2-secretstorage: SecretService DBus API (GNOME/KDE)')
+
+ cd "$srcdir/keyring-$pkgver-py2"
+ python2 setup.py install --root=$pkgdir --optimize=1
+
+ mv "$pkgdir"/usr/bin/keyring{,2}
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list