[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, January 23, 2016 @ 07:16:22
  Author: fyan
Revision: 158646

addpkg: python-contextlib2 0.5.1-1

Added:
  python-contextlib2/
  python-contextlib2/repos/
  python-contextlib2/trunk/
  python-contextlib2/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: python-contextlib2/trunk/PKGBUILD
===================================================================
--- python-contextlib2/trunk/PKGBUILD	                        (rev 0)
+++ python-contextlib2/trunk/PKGBUILD	2016-01-23 06:16:22 UTC (rev 158646)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Cedric Girard <girard.cedric at gmail.com>
+
+pkgbase=python-contextlib2
+_pypiname=contextlib2
+pkgname=(python-contextlib2 python2-contextlib2)
+pkgver=0.5.1
+pkgrel=1
+pkgdesc="contextlib2 is a backport of the standard library’s contextlib module to earlier Python versions"
+arch=('any')
+url="http://pypi.python.org/pypi/${_pypiname}"
+license=('PSF')
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("https://pypi.python.org/packages/source/${_pypiname:0:1}/${_pypiname}/${_pypiname}-$pkgver.tar.gz")
+md5sums=('b7f4c5a2b900c419b11b20f59838de1b')
+
+prepare() {
+  cp -a ${_pypiname}-$pkgver{,-py2}
+}
+
+build() {
+  cd "${srcdir}/${_pypiname}-$pkgver"
+  python setup.py build
+
+  cd "${srcdir}/${_pypiname}-$pkgver-py2"
+  python2 setup.py build
+}
+
+package_python-contextlib2() {
+  depends=('python')
+
+  cd ${_pypiname}-$pkgver
+  python setup.py install --root="${pkgdir}"
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-contextlib2() {
+  depends=('python2')
+
+  cd ${_pypiname}-$pkgver-py2
+  python2 setup.py install --root="${pkgdir}"
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}


Property changes on: python-contextlib2/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property