[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, January 25, 2016 @ 04:47:44
  Author: fyan
Revision: 158802

addpkg: lib32-libtheora 1.1.1-10

Added:
  lib32-libtheora/
  lib32-libtheora/repos/
  lib32-libtheora/trunk/
  lib32-libtheora/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: lib32-libtheora/trunk/PKGBUILD
===================================================================
--- lib32-libtheora/trunk/PKGBUILD	                        (rev 0)
+++ lib32-libtheora/trunk/PKGBUILD	2016-01-25 03:47:44 UTC (rev 158802)
@@ -0,0 +1,52 @@
+# Maintainer: Maxime Gauduin <alucryd at gmail.com>
+# Contributor: Nicky726 <nicky726 at gmail.com>
+# Contributor: Tom Killian <tom at archlinux.org>
+# Contributor: Rémy Oudompheng <remyoudompheng at gmail.com>
+
+pkgname=lib32-libtheora
+pkgver=1.1.1
+pkgrel=10
+pkgdesc='An open video codec developed by the Xiph.org'
+arch=('x86_64')
+url='http://www.xiph.org'
+license=('BSD')
+depends=('lib32-libogg' 'libtheora')
+makedepends=('gcc-multilib' 'lib32-libvorbis')
+source=("http://downloads.xiph.org/releases/theora/libtheora-${pkgver}.tar.bz2")
+sha256sums=('b6ae1ee2fa3d42ac489287d3ec34c5885730b1296f0801ae577a35193d3affbc')
+
+prepare() {
+  cd libtheora-${pkgver}
+
+  sed -i 's|AC_DEFINE(\[OC_X86_64_ASM\]|#AC_DEFINE(\[OC_X86_64_ASM\]|
+          s|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|' configure.ac
+}
+
+build() {
+  cd libtheora-${pkgver}
+
+  export CC='gcc -m32'
+  export CXX='g++ -m32'
+  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+
+  ./autogen.sh \
+    --prefix='/usr' \
+    --libdir='/usr/lib32' \
+    --with-pic \
+    --disable-examples \
+    --disable-static
+  make
+}
+
+package() {
+  cd libtheora-${pkgver}
+
+  make DESTDIR="${pkgdir}" install
+  rm -rf "${pkgdir}"/usr/{include,share}
+
+# License
+  install -dm 755 "${pkgdir}"/usr/share/licenses
+  ln -s libtheora "${pkgdir}"/usr/share/licenses/lib32-libtheora
+}
+
+# vim: ts=2 sw=2 et: