[arch-commits] Commit in (4 files)

Levente Polyak anthraxx at archlinux.org
Mon Jan 25 17:13:49 UTC 2016


    Date: Monday, January 25, 2016 @ 18:13:49
  Author: anthraxx
Revision: 158890

upgpkg: python-blist 1.3.6-4

Added:
  python-blist/
  python-blist/repos/
  python-blist/trunk/
  python-blist/trunk/PKGBUILD

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Added: python-blist/trunk/PKGBUILD
===================================================================
--- python-blist/trunk/PKGBUILD	                        (rev 0)
+++ python-blist/trunk/PKGBUILD	2016-01-25 17:13:49 UTC (rev 158890)
@@ -0,0 +1,56 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Aaron DeVore <aaron.devore at gmail.com>
+# Contributor: Chris Baker <baker.chris.3 at gmail.com>
+
+pkgbase=python-blist
+pkgname=('python-blist' 'python2-blist')
+_pkgname=blist
+pkgver=1.3.6
+pkgrel=4
+pkgdesc='List-like type with better asymptotic performance'
+url='http://stutzbachenterprises.com/blist'
+arch=('i686' 'x86_64')
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools')
+source=(${pkgbase}-${pkgver}.tar.gz::https://github.com/DanielStutzbach/blist/archive/v${pkgver}.tar.gz)
+sha512sums=('f46ded57aeb2a33fc5450420210d015aa37c2fc91034a771dfb1a184ef2655d8e5dc97bee61139059e6211569fcb7358f972071d3830733e9dbb8908e1b0e14c')
+
+prepare() {
+  cp -ra ${_pkgname}-${pkgver}{,-py2}
+}
+
+build() {
+  (cd ${_pkgname}-${pkgver}
+    python setup.py build
+  )
+  (cd ${_pkgname}-${pkgver}-py2
+    python2 setup.py build
+  )
+}
+
+check() {
+  (cd ${_pkgname}-${pkgver}
+    python setup.py test
+  )
+  (cd ${_pkgname}-${pkgver}-py2
+    python2 setup.py test
+  )
+}
+
+package_python-blist() {
+  depends=('python')
+  cd ${_pkgname}-${pkgver}
+  python setup.py install --skip-build -O1 --root="${pkgdir}"
+  install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm 644 README.rst "${pkgdir}/usr/share/doc/${pkgname}/README"
+}
+
+package_python2-blist() {
+  depends=('python2')
+  cd ${_pkgname}-${pkgver}-py2
+  python2 setup.py install --skip-build -O1 --root="${pkgdir}"
+  install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm 644 README.rst "${pkgdir}/usr/share/doc/${pkgname}/README"
+}
+
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list