[arch-commits] Commit in (4 files)
Felix Yan
felixonmars at archlinux.org
Fri Jul 8 03:25:30 UTC 2016
Date: Friday, July 8, 2016 @ 03:25:30
Author: felixonmars
Revision: 271155
addpkg: python-isort 4.2.5-1
Added:
python-isort/
python-isort/repos/
python-isort/trunk/
python-isort/trunk/PKGBUILD
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Added: python-isort/trunk/PKGBUILD
===================================================================
--- python-isort/trunk/PKGBUILD (rev 0)
+++ python-isort/trunk/PKGBUILD 2016-07-08 03:25:30 UTC (rev 271155)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Yaron de Leeuw <me at jarondl.net>
+
+pkgbase=python-isort
+pkgname=('python-isort' 'python2-isort')
+pkgver=4.2.5
+pkgrel=1
+pkgdesc="A Python utility / library to sort Python imports."
+arch=('any')
+url="https://github.com/timothycrosley/isort"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest' 'python2-pytest' 'python-mock' 'python2-mock')
+source=("git+https://github.com/timothycrosley/isort.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+ cp -a isort{,-py2}
+}
+
+build() {
+ cd "$srcdir"/isort
+ python setup.py build
+
+ cd "$srcdir"/isort-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/isort
+ python setup.py test
+
+ cd "$srcdir"/isort-py2
+ python2 setup.py test
+}
+
+package_python-isort() {
+ depends=('python-setuptools')
+
+ cd isort
+ python setup.py install --root="$pkgdir/" --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-isort() {
+ depends=('python2-setuptools')
+
+ cd isort-py2
+ python2 setup.py install --root="$pkgdir/" --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+ mv "$pkgdir"/usr/bin/isort{,2}
+}
Property changes on: python-isort/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list