[arch-commits] Commit in (4 files)
Kyle Keen
kkeen at archlinux.org
Sat Jul 16 02:34:38 UTC 2016
Date: Saturday, July 16, 2016 @ 02:34:38
Author: kkeen
Revision: 182977
pkginit: python-prompt_toolkit-1.0.3 for ipython-5.0.0
Added:
python-prompt_toolkit/
python-prompt_toolkit/repos/
python-prompt_toolkit/trunk/
python-prompt_toolkit/trunk/PKGBUILD
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Added: python-prompt_toolkit/trunk/PKGBUILD
===================================================================
--- python-prompt_toolkit/trunk/PKGBUILD (rev 0)
+++ python-prompt_toolkit/trunk/PKGBUILD 2016-07-16 02:34:38 UTC (rev 182977)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Kyle Keen <keenerd at gmail.com>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+pkgbase=python-prompt_toolkit
+pkgname=(python-prompt_toolkit python2-prompt_toolkit)
+_name=prompt_toolkit
+pkgver=1.0.3
+pkgrel=1
+pkgdesc="Library for building powerful interactive command lines in Python"
+arch=('any')
+depends=('python-pygments'
+ 'python-six'
+ 'python-wcwidth')
+makedepends=('python-setuptools' 'python2-setuptools'
+ 'python2-pygments' 'python2-six' 'python2-wcwidth')
+url="https://github.com/jonathanslenders/python-prompt-toolkit"
+license=('BSD')
+options=(!emptydirs)
+source=("https://files.pythonhosted.org/packages/source/p/$_name/$_name-$pkgver.tar.gz")
+md5sums=('6c4133d099603f496c761491043bf0ef')
+sha256sums=('805e026f0cbad27467e93f9dd3e3777718d401a62788c1e84ca038e967ad8ba2')
+
+prepare() {
+ cd "$srcdir"
+ cp -r $_name-$pkgver python2-$_name-$pkgver
+}
+
+build() {
+ cd "$srcdir/$_name-$pkgver"
+ python3 setup.py build
+
+ cd "$srcdir/python2-$_name-$pkgver"
+ python2 setup.py build
+}
+
+package_python-prompt_toolkit() {
+ cd "$srcdir/$_name-$pkgver"
+ python3 setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-prompt_toolkit() {
+ depends=('python2-pygments'
+ 'python2-six'
+ 'python2-wcwidth')
+ cd "$srcdir/python2-$_name-$pkgver"
+ python2 setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
Property changes on: python-prompt_toolkit/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list