[arch-commits] Commit in (4 files)
Felix Yan
felixonmars at archlinux.org
Thu Jul 21 15:26:49 UTC 2016
Date: Thursday, July 21, 2016 @ 15:26:49
Author: felixonmars
Revision: 183667
addpkg: python-pytest-flake8 0.5-1
Added:
python-pytest-flake8/
python-pytest-flake8/repos/
python-pytest-flake8/trunk/
python-pytest-flake8/trunk/PKGBUILD
----------+
PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
Added: python-pytest-flake8/trunk/PKGBUILD
===================================================================
--- python-pytest-flake8/trunk/PKGBUILD (rev 0)
+++ python-pytest-flake8/trunk/PKGBUILD 2016-07-21 15:26:49 UTC (rev 183667)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-pytest-flake8
+pkgname=('python-pytest-flake8' 'python2-pytest-flake8')
+pkgver=0.5
+pkgrel=1
+pkgdesc='pytest plugin to check FLAKE8 requirements'
+arch=('any')
+license=('MIT')
+url='http://github.com/tholo/pytest-flake8'
+makedepends=('python-pytest' 'python2-pytest' 'flake8' 'python2-flake8' 'git')
+source=("git+https://github.com/tholo/pytest-flake8#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+ cp -a pytest-flake8{,-py2}
+}
+
+build() {
+ cd "$srcdir"/pytest-flake8
+ python setup.py build
+
+ cd "$srcdir"/pytest-flake8-py2
+ python2 setup.py build
+}
+
+check() {
+ # Hack entry points by installing it
+
+ cd "$srcdir"/pytest-flake8
+ python setup.py install --root="$PWD/tmp_install" --optimize=1
+ PYTHONPATH="$PWD/tmp_install/usr/lib/python3.5/site-packages:$PYTHONPATH" py.test
+
+ cd "$srcdir"/pytest-flake8-py2
+ python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+ PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH" py.test2
+}
+
+package_python-pytest-flake8() {
+ depends=('python-pytest' 'flake8')
+
+ cd pytest-flake8
+ python setup.py install --root="$pkgdir" --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-pytest-flake8() {
+ depends=('python2-pytest' 'python2-flake8')
+
+ cd pytest-flake8-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1
+ install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:
Property changes on: python-pytest-flake8/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list