[arch-commits] Commit in lib32-curl/repos (3 files)

[Evangelos Foutras]

    Date: Thursday, March 3, 2016 @ 14:20:06
  Author: foutrelis
Revision: 164474

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-curl/repos/multilib-staging-x86_64/
  lib32-curl/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 164473, lib32-curl/trunk/PKGBUILD)
  lib32-curl/repos/multilib-staging-x86_64/curlbuild.h
    (from rev 164473, lib32-curl/trunk/curlbuild.h)

-------------+
 PKGBUILD    |   63 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 curlbuild.h |    9 ++++++++
 2 files changed, 72 insertions(+)

Copied: lib32-curl/repos/multilib-staging-x86_64/PKGBUILD (from rev 164473, lib32-curl/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2016-03-03 13:20:06 UTC (rev 164474)
@@ -0,0 +1,63 @@
+# $Id$
+# Maintainer: Daniel Wallace <danielwallace at aur.archlinux.org>
+# Contributor: Dave Reisner <dreisner at archlinux.org>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: Lucien Immink <l.immink at student.fnt.hvu.nl>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=lib32-curl
+_pkgname=curl
+pkgver=7.47.1
+pkgrel=2
+pkgdesc="An URL retrieval utility and library (32-bit)"
+arch=('x86_64')
+url="http://curl.haxx.se"
+license=('MIT')
+depends=('lib32-libssh2' 'lib32-krb5' 'lib32-libidn' "${_pkgname}")
+source=("http://curl.haxx.se/download/$_pkgname-$pkgver.tar.gz"{,.asc})
+md5sums=('3f9d1be7bf33ca4b8c8602820525302b'
+         'SKIP')
+validpgpkeys=('914C533DF9B2ADA2204F586D78E11C6B279D5C91') # Daniel Stenberg
+
+build() {
+  cd "$_pkgname-$pkgver"
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+  
+  ./configure \
+      --prefix=/usr \
+      --mandir=/usr/share/man \
+      --disable-dependency-tracking \
+      --disable-ldap \
+      --disable-ldaps \
+      --enable-ipv6 \
+      --enable-manual \
+      --enable-versioned-symbols \
+      --enable-threaded-resolver \
+      --with-gssapi \
+      --with-libidn \
+      --with-random=/dev/urandom \
+      --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
+      --libdir=/usr/lib32
+
+  make
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir" install
+
+  rm -rf "${pkgdir}"/usr/{share,bin}
+  
+  # license
+  install -d "$pkgdir/usr/share/licenses"
+  ln -s "$_pkgname" "$pkgdir/usr/share/licenses/$pkgname"
+
+  # devel
+  find "${pkgdir}/usr/include/curl" -type f -not -name curlbuild.h -delete
+  mv "$pkgdir/usr/include/curl/curlbuild.h" "$pkgdir/usr/include/$_pkgname/curlbuild-32.h"
+}

Copied: lib32-curl/repos/multilib-staging-x86_64/curlbuild.h (from rev 164473, lib32-curl/trunk/curlbuild.h)
===================================================================
--- multilib-staging-x86_64/curlbuild.h	                        (rev 0)
+++ multilib-staging-x86_64/curlbuild.h	2016-03-03 13:20:06 UTC (rev 164474)
@@ -0,0 +1,9 @@
+#include <bits/wordsize.h>
+
+#if __WORDSIZE == 32
+#include "curlbuild-32.h"
+#elif __WORDSIZE == 64
+#include "curlbuild-64.h"
+#else
+#error "Unknown word size"
+#endif