[arch-commits] Commit in (4 files)
Balló György
bgyorgy at archlinux.org
Fri Mar 4 11:02:27 UTC 2016
Date: Friday, March 4, 2016 @ 12:02:26
Author: bgyorgy
Revision: 164721
Move budgie-desktop from AUR with 48 votes
Added:
budgie-desktop/
budgie-desktop/trunk/
budgie-desktop/trunk/PKGBUILD
budgie-desktop/trunk/budgie-desktop.install
------------------------+
PKGBUILD | 56 +++++++++++++++++++++++++++++++++++++++++++++++
budgie-desktop.install | 12 ++++++++++
2 files changed, 68 insertions(+)
Added: budgie-desktop/trunk/PKGBUILD
===================================================================
--- budgie-desktop/trunk/PKGBUILD (rev 0)
+++ budgie-desktop/trunk/PKGBUILD 2016-03-04 11:02:26 UTC (rev 164721)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=budgie-desktop
+pkgver=10.2.4
+pkgrel=2
+pkgdesc="Modern desktop environment from the Solus Project"
+arch=('i686' 'x86_64')
+url="https://solus-project.com/budgie"
+license=('GPL' 'LGPL')
+depends=('gnome-bluetooth' 'gnome-menus' 'gnome-session' 'gnome-themes-standard' 'libpeas' 'libwnck3' 'mutter')
+makedepends=('autoconf-archive' 'git' 'gobject-introspection' 'intltool' 'vala')
+optdepends=('gnome-backgrounds: Default background'
+ 'gnome-control-center: System settings'
+ 'gnome-screensaver: Lock screen'
+ 'network-manager-applet: Network management')
+install=$pkgname.install
+source=("https://github.com/solus-project/budgie-desktop/releases/download/v$pkgver/$pkgname-$pkgver.tar.xz"
+ "git+https://github.com/City-busz/budgie-helper.git#commit=da4733a")
+sha256sums=('b01e7be9349cbc26cd77db74a0c138d21c31d8bad21a02b31828014b416256f7'
+ 'SKIP')
+
+prepare() {
+ cd $pkgname-$pkgver
+ # Disable workspaces applet as it's broken
+ # https://github.com/solus-project/budgie-desktop/issues/302
+ sed -i ':a;N;$!ba;s/ \\\n\tworkspaces//' panel/applets/Makefile.am
+ autoreconf -fi
+
+ cd "$srcdir/budgie-helper"
+ # Provide better compatibility for GNOME
+ # https://github.com/solus-project/budgie-desktop/issues/261
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname-$pkgver
+ ./configure --prefix=/usr --sysconfdir=/etc
+
+ #https://bugzilla.gnome.org/show_bug.cgi?id=656231
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+ make
+
+ cd "$srcdir/budgie-helper"
+ ./configure --prefix=/usr --sysconfdir=/etc --disable-schemas-compile --disable-Werror
+ make
+}
+
+package() {
+ cd $pkgname-$pkgver
+ make DESTDIR="$pkgdir" install
+
+ cd "$srcdir/budgie-helper"
+ make DESTDIR="$pkgdir" install
+}
Property changes on: budgie-desktop/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: budgie-desktop/trunk/budgie-desktop.install
===================================================================
--- budgie-desktop/trunk/budgie-desktop.install (rev 0)
+++ budgie-desktop/trunk/budgie-desktop.install 2016-03-04 11:02:26 UTC (rev 164721)
@@ -0,0 +1,12 @@
+post_install() {
+ glib-compile-schemas usr/share/glib-2.0/schemas
+ gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+post_upgrade() {
+ post_install
+}
+
+post_remove() {
+ post_install
+}
More information about the arch-commits
mailing list