[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, March 7, 2016 @ 15:18:01
  Author: fyan
Revision: 165514

addpkg: python-cmd2 0.6.8-1

Added:
  python-cmd2/
  python-cmd2/repos/
  python-cmd2/trunk/
  python-cmd2/trunk/PKGBUILD

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Added: python-cmd2/trunk/PKGBUILD
===================================================================
--- python-cmd2/trunk/PKGBUILD	                        (rev 0)
+++ python-cmd2/trunk/PKGBUILD	2016-03-07 14:18:01 UTC (rev 165514)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+
+pkgbase=python-cmd2
+pkgname=(python-cmd2 python2-cmd2)
+pkgver=0.6.8
+_commit=3ed12b6154320d6e3e89c5aace04b7e5ac9bed2c
+pkgrel=1
+pkgdesc="Extra features for standard library's cmd module"
+arch=('any')
+url="https://github.com/python-cmd2/cmd2"
+license=('MIT')
+makedepends=('git' 'python-setuptools' 'python2-setuptools' 'python-pyparsing' 'python2-pyparsing')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("git+https://github.com/python-cmd2/cmd2.git#commit=$_commit")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a cmd2{,-py2}
+}
+
+build() {
+  cd "$srcdir"/cmd2
+  python setup.py build
+
+  cd "$srcdir"/cmd2-py2
+  python2 setup.py build
+}
+
+check() {
+  # Tests will be available in next release
+
+  cd "$srcdir"/cmd2
+  # python setup.py ptr
+
+  cd "$srcdir"/cmd2-py2
+  # python2 setup.py ptr
+}
+
+package_python-cmd2() {
+  depends=('python-pyparsing')
+
+  cd "$srcdir"/cmd2
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-cmd2() {
+  depends=('python2-pyparsing')
+
+  cd "$srcdir"/cmd2-py2
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-cmd2/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property