[arch-commits] Commit in (5 files)
Levente Polyak
anthraxx at archlinux.org
Sat Mar 12 00:56:04 UTC 2016
Date: Saturday, March 12, 2016 @ 01:56:04
Author: anthraxx
Revision: 166182
addpkg: linssid 2.7-3
Added:
linssid/
linssid/repos/
linssid/trunk/
linssid/trunk/PKGBUILD
linssid/trunk/linssid.install
-----------------+
PKGBUILD | 36 ++++++++++++++++++++++++++++++++++++
linssid.install | 15 +++++++++++++++
2 files changed, 51 insertions(+)
Added: linssid/trunk/PKGBUILD
===================================================================
--- linssid/trunk/PKGBUILD (rev 0)
+++ linssid/trunk/PKGBUILD 2016-03-12 00:56:04 UTC (rev 166182)
@@ -0,0 +1,36 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Jacques Fontaine <waitnsea at free.fr>
+# Contributor: Ryan Young <ryan31415926535 at gmail.com>
+
+pkgname=linssid
+pkgver=2.7
+pkgrel=3
+pkgdesc='Graphical wireless scanner for Linux'
+url='https://sourceforge.net/projects/linssid/'
+arch=('i686' 'x86_64')
+license=('GPL3')
+depends=('qt5-base' 'qt5-svg' 'libxkbcommon-x11' 'iw' 'wireless_tools' 'xdg-utils' 'desktop-file-utils' 'gtk-update-icon-cache')
+makedepends=('boost')
+optdepends=('sudo: privilege escalation to use wireless tools')
+install=linssid.install
+source=(${pkgname}-${pkgver}.tar.gz::https://downloads.sourceforge.net/${pkgname}/${pkgname}_$pkgver.orig.tar.gz)
+sha512sums=('33e69b0491bee74453cb71befb3a314da7766f12d2c1a21e947cf1d068b2941162eb72ab53989d9e5e5e2c8f2dd051576d0bfb775835d648eb9b1fc8b046a0cb')
+
+prepare() {
+ cd ${pkgname}-${pkgver}
+ # build workarounds, credit 'czerwonyd'
+ sed -e 's/QT_STATIC_CONST/static const/g' -i qwt-lib/src/qwt_transform.h
+ sed -e 's/QT_STATIC_CONST_IMPL/const/g' -i qwt-lib/src/qwt_transform.cpp
+}
+build() {
+ cd ${pkgname}-${pkgver}
+ qmake-qt5
+ make
+}
+
+package() {
+ cd ${pkgname}-${pkgver}
+ make INSTALL_ROOT="${pkgdir}" install
+}
+
+# vim: ts=2 sw=2 et:
Added: linssid/trunk/linssid.install
===================================================================
--- linssid/trunk/linssid.install (rev 0)
+++ linssid/trunk/linssid.install 2016-03-12 00:56:04 UTC (rev 166182)
@@ -0,0 +1,15 @@
+post_install() {
+ update-desktop-database -q
+ gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+post_upgrade() {
+ post_install $1
+}
+
+post_remove() {
+ update-desktop-database -q
+ gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list