[arch-commits] Commit in python-zope-testrunner/repos (2 files)

[Felix Yan]

    Date: Wednesday, May 4, 2016 @ 06:38:04
  Author: fyan
Revision: 173650

archrelease: copy trunk to community-testing-any

Added:
  python-zope-testrunner/repos/community-testing-any/
  python-zope-testrunner/repos/community-testing-any/PKGBUILD
    (from rev 173649, python-zope-testrunner/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: python-zope-testrunner/repos/community-testing-any/PKGBUILD (from rev 173649, python-zope-testrunner/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2016-05-04 04:38:04 UTC (rev 173650)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=('python-zope-testrunner' 'python2-zope-testrunner')
+pkgver=4.5.0
+pkgrel=2
+pkgdesc="Zope testrunner script"
+arch=('any')
+url="https://github.com/zopefoundation/zope.testrunner"
+license=('ZPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-zope-interface'
+             'python2-zope-interface' 'python-zope-exceptions' 'python2-zope-exceptions'
+             'python-six' 'python2-six' 'git')
+checkdepends=('python-nose' 'python2-nose' 'python-zope-testing' 'python2-zope-testing'
+              'python2-subunit')
+source=("git+https://github.com/zopefoundation/zope.testrunner.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a zope.testrunner{,-py2}
+}
+
+build() {
+  cd "$srcdir"/zope.testrunner
+  python setup.py build
+
+  cd "$srcdir"/zope.testrunner-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/zope.testrunner
+  python setup.py test
+
+  cd "$srcdir"/zope.testrunner-py2
+  python2 setup.py test
+}
+
+package_python-zope-testrunner() {
+  depends=('python-setuptools' 'python-zope-interface' 'python-zope-exceptions' 'python-six')
+
+  cd zope.testrunner
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-zope-testrunner() {
+  depends=('python2-setuptools' 'python2-zope-interface' 'python2-zope-exceptions' 'python2-six')
+
+  cd zope.testrunner-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  mv "$pkgdir/usr/bin/zope-testrunner"{,2}
+}
+
+# vim:set ts=2 sw=2 et: