[arch-commits] Commit in (6 files)

[Alexander Rødseth]

    Date: Saturday, May 14, 2016 @ 14:17:01
  Author: arodseth
Revision: 175342

Add C++14 library from AUR

Added:
  libcorrade/
  libcorrade/repos/
  libcorrade/repos/community-i686/
  libcorrade/repos/community-x86_64/
  libcorrade/trunk/
  libcorrade/trunk/PKGBUILD

----------+
 PKGBUILD |   33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

Added: libcorrade/trunk/PKGBUILD
===================================================================
--- libcorrade/trunk/PKGBUILD	                        (rev 0)
+++ libcorrade/trunk/PKGBUILD	2016-05-14 12:17:01 UTC (rev 175342)
@@ -0,0 +1,33 @@
+# Maintainer: Alexander F Rødseth <xyproto at archlinux.org>
+# Contributor: mosra <mosra at centrum.cz>
+
+pkgname=libcorrade
+pkgver=2016.05.13
+pkgrel=1
+pkgdesc='Utility library for C++11/C++14'
+arch=('x86_64' 'i686')
+url='http://mosra.cz/blog/corrade.php'
+license=('MIT')
+makedepends=('cmake' 'git' 'ninja')
+depends=('gcc-libs')
+source=('git://github.com/mosra/corrade.git#commit=142b2a7241')
+sha1sums=('SKIP')
+
+build() {
+  mkdir -p build
+  cd build
+
+  cmake ../corrade \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -GNinja
+  ninja
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C build install
+  install -Dm644 "corrade/COPYING" \
+    "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}
+
+# vim:set ts=2 sw=2 et: