[arch-commits] Commit in python-doublex/repos (community-any community-any/PKGBUILD)

[Felix Yan]

    Date: Monday, May 16, 2016 @ 07:54:23
  Author: fyan
Revision: 175444

archrelease: copy trunk to community-any

Added:
  python-doublex/repos/community-any/
  python-doublex/repos/community-any/PKGBUILD
    (from rev 175443, python-doublex/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-doublex/repos/community-any/PKGBUILD (from rev 175443, python-doublex/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2016-05-16 05:54:23 UTC (rev 175444)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-doublex
+pkgname=('python-doublex' 'python2-doublex')
+pkgver=1.8.2
+pkgrel=1
+pkgdesc="Powerful test doubles framework for Python"
+arch=('any')
+license=('GPL')
+url="https://github.com/davidvilla/python-doublex"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pyhamcrest' 'python2-pyhamcrest' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/davidvilla/python-doublex.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a python-doublex{,-py2}
+}
+
+build() {
+  cd "$srcdir"/python-doublex
+  python setup.py build
+
+  cd "$srcdir"/python-doublex-py2
+  python2 setup.py build
+}
+
+check() {
+  # https://github.com/davidvilla/python-doublex/issues/3
+
+  cd "$srcdir"/python-doublex
+  python setup.py test || warning "Tests failed"
+
+  cd "$srcdir"/python-doublex-py2
+  python2 setup.py test || warning "Tests failed"
+}
+
+package_python-doublex() {
+  depends=('python-pyhamcrest')
+
+  cd python-doublex
+  python setup.py install --root="$pkgdir" --optimize=1
+  rm "$pkgdir"/usr/README.rst
+}
+
+package_python2-doublex() {
+  depends=('python2-pyhamcrest')
+
+  cd python-doublex-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  rm "$pkgdir"/usr/README.rst
+}