[arch-commits] Commit in (4 files)

[Pierre Schmitz]

    Date: Wednesday, May 18, 2016 @ 12:38:36
  Author: pierre
Revision: 268281

Add composer without the php prefix

Added:
  composer/
  composer/repos/
  composer/trunk/
  composer/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: composer/trunk/PKGBUILD
===================================================================
--- composer/trunk/PKGBUILD	                        (rev 0)
+++ composer/trunk/PKGBUILD	2016-05-18 10:38:36 UTC (rev 268281)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Pierre Schmitz <pierre at archlinux.de>
+
+pkgname=composer
+pkgver=1.1.1
+pkgrel=1
+pkgdesc="Dependency Manager for PHP"
+arch=('any')
+license=('MIT')
+url='https://getcomposer.org/'
+depends=('php')
+makedepends=('git')
+replaces=('php-composer')
+conflicts=('php-composer')
+provides=('php-composer')
+source=("${pkgname}::git+https://github.com/composer/composer.git#tag=${pkgver}"
+        "${pkgname}-${pkgver}.phar::https://getcomposer.org/download/${pkgver}/composer.phar")
+md5sums=('SKIP'
+         '05d30d20be1c94c9edc02756420a7d10')
+
+prepare() {
+	cd ${srcdir}/${pkgname}
+
+	php ${srcdir}/${pkgname}-${pkgver}.phar -n install --no-dev --prefer-dist
+}
+
+build() {
+	cd ${srcdir}/${pkgname}
+
+	php -d phar.readonly=Off bin/compile
+}
+
+check() {
+	cd ${srcdir}/${pkgname}
+
+	# check if the upstream build and ours differ
+	diff -q ${srcdir}/${pkgname}-${pkgver}.phar composer.phar
+
+	# Install the dev dependencies to run the unit tests
+	bin/composer -n install --prefer-dist
+	vendor/bin/phpunit
+}
+
+package() {
+	cd ${srcdir}/${pkgname}
+
+	install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+	install -Dm755 composer.phar ${pkgdir}/usr/bin/composer
+}


Property changes on: composer/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property