[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, May 20, 2016 @ 07:38:19
  Author: fyan
Revision: 175777

addpkg: python-ddt 1.0.1-1

Added:
  python-ddt/
  python-ddt/repos/
  python-ddt/trunk/
  python-ddt/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: python-ddt/trunk/PKGBUILD
===================================================================
--- python-ddt/trunk/PKGBUILD	                        (rev 0)
+++ python-ddt/trunk/PKGBUILD	2016-05-20 05:38:19 UTC (rev 175777)
@@ -0,0 +1,51 @@
+# $Id: PKGBUILD 175443 2016-05-16 05:54:00Z fyan $
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-ddt
+pkgname=('python-ddt' 'python2-ddt')
+pkgver=1.0.1
+pkgrel=1
+pkgdesc="Data-Driven/Decorated Tests"
+arch=('any')
+license=('MIT')
+url="https://github.com/txels/ddt"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/txels/ddt.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a ddt{,-py2}
+}
+
+build() {
+  cd "$srcdir"/ddt
+  python setup.py build
+
+  cd "$srcdir"/ddt-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/ddt
+  nosetests3
+
+  cd "$srcdir"/ddt-py2
+  nosetests2
+}
+
+package_python-ddt() {
+  depends=('python')
+
+  cd ddt
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.md
+}
+
+package_python2-ddt() {
+  depends=('python2')
+
+  cd ddt-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.md
+}