[arch-commits] Commit in python-jsbeautifier/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Wed Nov 2 06:15:28 UTC 2016
Date: Wednesday, November 2, 2016 @ 06:15:27
Author: felixonmars
Revision: 194317
archrelease: copy trunk to community-any
Added:
python-jsbeautifier/repos/community-any/
python-jsbeautifier/repos/community-any/PKGBUILD
(from rev 194316, python-jsbeautifier/trunk/PKGBUILD)
----------+
PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
Copied: python-jsbeautifier/repos/community-any/PKGBUILD (from rev 194316, python-jsbeautifier/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD (rev 0)
+++ community-any/PKGBUILD 2016-11-02 06:15:27 UTC (rev 194317)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-jsbeautifier
+pkgname=('python-jsbeautifier' 'python2-jsbeautifier')
+pkgver=1.6.4
+pkgrel=1
+pkgdesc='JavaScript unobfuscator and beautifier'
+arch=('any')
+license=('MIT')
+url='https://github.com/beautify-web/js-beautify'
+makedepends=('python-setuptools' 'python2-setuptools' 'python-editorconfig' 'python2-editorconfig'
+ 'git')
+checkdepends=('python-pytest' 'python2-pytest')
+source=("git+https://github.com/beautify-web/js-beautify.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+ cp -a js-beautify{,-py2}
+}
+
+build() {
+ cd "$srcdir"/js-beautify/python
+ python setup.py build
+
+ cd "$srcdir"/js-beautify-py2/python
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/js-beautify/python
+ python setup.py test
+
+ cd "$srcdir"/js-beautify-py2/python
+ python2 setup.py test
+}
+
+package_python-jsbeautifier() {
+ depends=('python-six' 'python-editorconfig')
+
+ cd js-beautify/python
+ python setup.py install --root="$pkgdir" --optimize=1
+ install -D -m644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-jsbeautifier() {
+ depends=('python2-six' 'python2-editorconfig')
+
+ cd js-beautify-py2/python
+ python2 setup.py install --root="$pkgdir" --optimize=1
+ install -D -m644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+ mv "$pkgdir"/usr/bin/js-beautify{,2}
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list