[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, November 4, 2016 @ 06:20:39
  Author: felixonmars
Revision: 194639

addpkg: haskell-microlens-aeson 2.1.1.1-1

Added:
  haskell-microlens-aeson/
  haskell-microlens-aeson/repos/
  haskell-microlens-aeson/trunk/
  haskell-microlens-aeson/trunk/PKGBUILD

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Added: haskell-microlens-aeson/trunk/PKGBUILD
===================================================================
--- haskell-microlens-aeson/trunk/PKGBUILD	                        (rev 0)
+++ haskell-microlens-aeson/trunk/PKGBUILD	2016-11-04 06:20:39 UTC (rev 194639)
@@ -0,0 +1,41 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=microlens-aeson
+pkgname=haskell-microlens-aeson
+pkgver=2.1.1.1
+pkgrel=1
+pkgdesc="Law-abiding lenses for Aeson, using microlens"
+url="http://github.com/fosskers/microlens-aeson/"
+license=('MIT')
+arch=('i686' 'x86_64')
+depends=('ghc=8.0.1' 'haskell-aeson' 'haskell-attoparsec' 'haskell-microlens' 'haskell-scientific'
+         'haskell-text' 'haskell-unordered-containers' 'haskell-vector')
+source=(http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+md5sums=('9e8031f4ffcaf831bd08e7add445b21a')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    runhaskell Setup configure -O --enable-library-profiling --enable-shared \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup haddock --hoogle --html
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"
+    ln -s "/usr/share/doc/${pkgname}/html" "${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


Property changes on: haskell-microlens-aeson/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property