[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, November 18, 2016 @ 07:13:08
  Author: felixonmars
Revision: 281031

addpkg: python-constantly 15.1.0-1

Added:
  python-constantly/
  python-constantly/repos/
  python-constantly/trunk/
  python-constantly/trunk/PKGBUILD

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Added: python-constantly/trunk/PKGBUILD
===================================================================
--- python-constantly/trunk/PKGBUILD	                        (rev 0)
+++ python-constantly/trunk/PKGBUILD	2016-11-18 07:13:08 UTC (rev 281031)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-constantly
+pkgname=('python-constantly' 'python2-constantly')
+pkgver=15.1.0
+pkgrel=1
+pkgdesc='Symbolic constants in Python'
+arch=('any')
+license=('MIT')
+url='https://github.com/twisted/constantly'
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-twisted' 'python2-twisted')
+source=("git+https://github.com/twisted/constantly.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a constantly{,-py2}
+}
+
+build() {
+  cd "$srcdir"/constantly
+  python setup.py build
+
+  cd "$srcdir"/constantly-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/constantly
+  python setup.py ptr
+
+  cd "$srcdir"/constantly-py2
+  python2 setup.py ptr
+}
+
+package_python-constantly() {
+  depends=('python')
+
+  cd constantly
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-constantly() {
+  depends=('python2')
+
+  cd constantly-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-constantly/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property