[arch-commits] Commit in (okular okular/kde-unstable okular/kde-unstable/PKGBUILD)

[Antonio Rojas]

    Date: Friday, November 18, 2016 @ 23:19:54
  Author: arojas
Revision: 281275

Add KF5 okular

Added:
  okular/
  okular/kde-unstable/
  okular/kde-unstable/PKGBUILD

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Added: okular/kde-unstable/PKGBUILD
===================================================================
--- okular/kde-unstable/PKGBUILD	                        (rev 0)
+++ okular/kde-unstable/PKGBUILD	2016-11-18 23:19:54 UTC (rev 281275)
@@ -0,0 +1,41 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=okular
+pkgver=16.11.80
+pkgrel=1
+pkgdesc='Document Viewer'
+arch=(i686 x86_64)
+url="http://kde.org/applications/graphics/okular/"
+license=(GPL LGPL FDL)
+groups=(kde-applications kdegraphics)
+depends=(chmlib djvulibre libspectre libkexiv2 poppler-qt5 qca-qt5 kpty khtml kactivities threadweaver)
+makedepends=(extra-cmake-modules ebook-tools kdegraphics-mobipocket kdoctools python)
+optdepends=('ebook-tools: mobi and epub support'
+            'kdegraphics-mobipocket: mobi support')
+conflicts=(kdegraphics-okular)
+replaces=(kdegraphics-okular)
+source=("http://download.kde.org/unstable/applications/${pkgver}/src/okular-${pkgver}.tar.xz"{,.sig})
+sha1sums=('813e554f0ac923f8848a4d7d5e14a82df44e0fbb'
+          'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}