[arch-commits] Commit in evolution-data-server/repos (4 files)

[Evangelos Foutras]

    Date: Monday, November 28, 2016 @ 12:27:17
  Author: foutrelis
Revision: 282160

archrelease: copy trunk to staging-i686, staging-x86_64

Added:
  evolution-data-server/repos/staging-i686/
  evolution-data-server/repos/staging-i686/PKGBUILD
    (from rev 282159, evolution-data-server/trunk/PKGBUILD)
  evolution-data-server/repos/staging-x86_64/
  evolution-data-server/repos/staging-x86_64/PKGBUILD
    (from rev 282159, evolution-data-server/trunk/PKGBUILD)

-------------------------+
 staging-i686/PKGBUILD   |   52 ++++++++++++++++++++++++++++++++++++++++++++++
 staging-x86_64/PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 104 insertions(+)

Copied: evolution-data-server/repos/staging-i686/PKGBUILD (from rev 282159, evolution-data-server/trunk/PKGBUILD)
===================================================================
--- staging-i686/PKGBUILD	                        (rev 0)
+++ staging-i686/PKGBUILD	2016-11-28 12:27:17 UTC (rev 282160)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=evolution-data-server
+pkgver=3.22.2
+pkgrel=2
+pkgdesc="Centralized access to appointments and contacts"
+url="https://wiki.gnome.org/Apps/Evolution"
+arch=(i686 x86_64)
+depends=(gnome-online-accounts nss krb5 libgweather libical db libgdata libphonenumber)
+makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git gnome-common)
+license=(GPL)
+_commit=828f3d954f3ca5ded5bc89c0231ff74a58114dcf  # tags/EVOLUTION_DATA_SERVER_3_22_2^0
+source=("git://git.gnome.org/evolution-data-server#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --with-openldap=yes \
+      --libexecdir=/usr/lib/evolution-data-server \
+      --with-krb5=/usr --with-libdb=/usr --with-phonenumber=/usr \
+      --enable-vala-bindings --disable-uoa \
+      --enable-gtk-doc
+
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  cd $pkgname
+  # libedata-book tests fail because they try to
+  # mkdir /usr/lib/evolution-data-server/camel-providers
+  make check -k || :
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}

Copied: evolution-data-server/repos/staging-x86_64/PKGBUILD (from rev 282159, evolution-data-server/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2016-11-28 12:27:17 UTC (rev 282160)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=evolution-data-server
+pkgver=3.22.2
+pkgrel=2
+pkgdesc="Centralized access to appointments and contacts"
+url="https://wiki.gnome.org/Apps/Evolution"
+arch=(i686 x86_64)
+depends=(gnome-online-accounts nss krb5 libgweather libical db libgdata libphonenumber)
+makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git gnome-common)
+license=(GPL)
+_commit=828f3d954f3ca5ded5bc89c0231ff74a58114dcf  # tags/EVOLUTION_DATA_SERVER_3_22_2^0
+source=("git://git.gnome.org/evolution-data-server#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --with-openldap=yes \
+      --libexecdir=/usr/lib/evolution-data-server \
+      --with-krb5=/usr --with-libdb=/usr --with-phonenumber=/usr \
+      --enable-vala-bindings --disable-uoa \
+      --enable-gtk-doc
+
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  cd $pkgname
+  # libedata-book tests fail because they try to
+  # mkdir /usr/lib/evolution-data-server/camel-providers
+  make check -k || :
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}