[arch-commits] Commit in (kexi kexi/trunk kexi/trunk/PKGBUILD)

[Antonio Rojas]

    Date: Wednesday, October 5, 2016 @ 10:26:46
  Author: arojas
Revision: 277741

Add standalone kexi package, split from calligra

Added:
  kexi/
  kexi/trunk/
  kexi/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: kexi/trunk/PKGBUILD
===================================================================
--- kexi/trunk/PKGBUILD	                        (rev 0)
+++ kexi/trunk/PKGBUILD	2016-10-05 10:26:46 UTC (rev 277741)
@@ -0,0 +1,39 @@
+# $Id$
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=kexi
+pkgver=3.0.0
+pkgrel=1
+pkgdesc="A visual database applications creator"
+arch=(i686 x86_64)
+url="http://www.kexi-project.org/"
+license=(GPL2)
+depends=(kdb kreport ktexteditor qt5-webkit)
+makedepends=(extra-cmake-modules python qt5-tools breeze-icons marble libmariadbclient postgresql)
+conflicts=(calligra-kexi)
+replaces=(calligra-kexi)
+groups=(calligra)
+source=("http://download.kde.org/stable/$pkgname/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha1sums=('f7e7919f0a13707cdf2992da9c095ffa14cd510d'
+          'SKIP')
+validpgpkeys=(4866BAF713B465677A4059643C7C0E201B6524DB) # Jarosław Staniek <staniek at kde.org>
+
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_TESTING=OFF \
+    -DKDE_INSTALL_LIBDIR=lib
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}


Property changes on: kexi/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property