[arch-commits] Commit in python-cssselect/repos (testing-any testing-any/PKGBUILD)

[Felix Yan]

    Date: Friday, October 21, 2016 @ 18:01:39
  Author: felixonmars
Revision: 279124

archrelease: copy trunk to testing-any

Added:
  python-cssselect/repos/testing-any/
  python-cssselect/repos/testing-any/PKGBUILD
    (from rev 279123, python-cssselect/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: python-cssselect/repos/testing-any/PKGBUILD (from rev 279123, python-cssselect/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2016-10-21 18:01:39 UTC (rev 279124)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Simon Sapin <simon dot sapin at exyr dot org>
+
+pkgbase=python-cssselect
+pkgname=('python-cssselect' 'python2-cssselect')
+pkgver=1.0.0
+pkgrel=1
+license=('BSD')
+arch=('any')
+url="http://pypi.python.org/pypi/cssselect"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-lxml' 'python2-lxml')
+source=("git+https://github.com/scrapy/cssselect.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a cssselect{,-py2}
+}
+
+build() {
+  cd "$srcdir"/cssselect
+  python setup.py build
+
+  cd "$srcdir"/cssselect-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/cssselect
+  python setup.py ptr
+
+  cd "$srcdir"/cssselect-py2
+  python2 setup.py ptr
+}
+
+package_python-cssselect() {
+  pkgdesc="A Python3 library that parses CSS3 Selectors and translates them to XPath 1.0"
+  depends=('python')
+
+  cd cssselect
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-cssselect() {
+  pkgdesc="A Python2 library that parses CSS3 Selectors and translates them to XPath 1.0"
+  depends=('python2')
+
+  cd cssselect-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}