[arch-commits] Commit in (4 files)

[Rémy Oudompheng]

    Date: Sunday, October 23, 2016 @ 17:01:22
  Author: remy
Revision: 279183

New package perl-sort-key

Imported from AUR and adapted for uniform packaging.
Added as a dependency of biber 2.6

Added:
  perl-sort-key/
  perl-sort-key/repos/
  perl-sort-key/trunk/
  perl-sort-key/trunk/PKGBUILD

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Added: perl-sort-key/trunk/PKGBUILD
===================================================================
--- perl-sort-key/trunk/PKGBUILD	                        (rev 0)
+++ perl-sort-key/trunk/PKGBUILD	2016-10-23 17:01:22 UTC (rev 279183)
@@ -0,0 +1,40 @@
+# $Id$
+# Maintainer: Rémy Oudompheng <remy at archlinux.org>
+# Contributor: Piotr Rogoza <piotr.r.public at gmail dot com>
+# Contributor: Alessandro Sagratini <ale_sagra at hotmail dot com>
+
+pkgname=perl-sort-key
+pkgver=1.33
+pkgrel=1
+_author="S/SA/SALVA"
+_perlmod="Sort-Key"
+pkgdesc="Sort::Key - the fastest way to sort anything in Perl"
+arch=("i686" "x86_64")
+url=http://search.cpan.org/dist/sort-sort/
+license=('GPL' 'PerlArtistic')
+depends=(perl)
+options=(!emptydirs)
+source=("http://search.cpan.org/CPAN/authors/id/$_author/$_perlmod-$pkgver.tar.gz")
+sha256sums=('ed6a4ccfab094c9cd164f564024e98bd21d94f4312ccac4d6246d22b34081acf')
+
+build() {
+    cd "${srcdir}/${_perlmod}-${pkgver}"
+
+    # install module in vendor directories.
+    PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
+    make
+}
+
+check() {
+    cd "${srcdir}/${_perlmod}-${pkgver}"
+    unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
+    export PERL_MM_USE_DEFAULT=1
+    make test
+}
+
+package() {
+    cd "${srcdir}/${_perlmod}-${pkgver}"
+    unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
+    make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
+}
+


Property changes on: perl-sort-key/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property