[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, September 16, 2016 @ 03:26:25
  Author: felixonmars
Revision: 189376

addpkg: haskell-quickcheck-io 0.1.3-1

Added:
  haskell-quickcheck-io/
  haskell-quickcheck-io/repos/
  haskell-quickcheck-io/trunk/
  haskell-quickcheck-io/trunk/PKGBUILD

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Added: haskell-quickcheck-io/trunk/PKGBUILD
===================================================================
--- haskell-quickcheck-io/trunk/PKGBUILD	                        (rev 0)
+++ haskell-quickcheck-io/trunk/PKGBUILD	2016-09-16 03:26:25 UTC (rev 189376)
@@ -0,0 +1,40 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=quickcheck-io
+pkgname=haskell-quickcheck-io
+pkgver=0.1.3
+pkgrel=1
+pkgdesc="Use HUnit assertions as QuickCheck properties"
+url="https://github.com/hspec/quickcheck-io"
+license=('MIT')
+arch=('i686' 'x86_64')
+depends=('ghc=8.0.1' 'haskell-hunit' 'haskell-quickcheck')
+source=(http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+md5sums=('1db16222c0561d8ec67b82995ca095e0')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    runhaskell Setup configure -O --enable-library-profiling --enable-shared \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup haddock --hoogle --html
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"
+    ln -s "/usr/share/doc/${pkgname}/html" "${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


Property changes on: haskell-quickcheck-io/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property