[arch-commits] Commit in (ripgrep ripgrep/repos ripgrep/trunk ripgrep/trunk/PKGBUILD)

[Sven-Hendrik Haase]

    Date: Saturday, September 24, 2016 @ 20:10:26
  Author: svenstaro
Revision: 190455

Move ripgrep from AUR

Added:
  ripgrep/
  ripgrep/repos/
  ripgrep/trunk/
  ripgrep/trunk/PKGBUILD

----------+
 PKGBUILD |   30 ++++++++++++++++++++++++++++++
 1 file changed, 30 insertions(+)

Added: ripgrep/trunk/PKGBUILD
===================================================================
--- ripgrep/trunk/PKGBUILD	                        (rev 0)
+++ ripgrep/trunk/PKGBUILD	2016-09-24 20:10:26 UTC (rev 190455)
@@ -0,0 +1,30 @@
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: Andrew Gallant <jamslam at gmail.com>
+pkgname=ripgrep
+pkgver=0.1.17
+pkgrel=1
+pkgdesc="A search tool that combines the usability of ag with the raw speed of grep"
+arch=('i686' 'x86_64')
+url="https://github.com/BurntSushi/ripgrep"
+license=('MIT' 'UNLICENSE')
+makedepends=('cargo')
+source=("https://github.com/BurntSushi/$pkgname/archive/$pkgver.tar.gz")
+sha256sums=('ced856378c4ca625e4798ccae85418badd22e099fc324bcb162df51824808622')
+
+build() {
+  cd "$pkgname-$pkgver"
+  cargo build --release
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  install -Dm755 "target/release/rg" "$pkgdir/usr/bin/rg"
+
+  install -Dm644 "doc/rg.1" "$pkgdir/usr/share/man/man1/rg.1"
+  install -Dm644 "README-NEW.md" "$pkgdir/usr/share/doc/${pkgname}/README.md"
+
+  install -Dm644 "COPYING" "$pkgdir/usr/share/licenses/${pkgname}/COPYING"
+  install -Dm644 "LICENSE-MIT" "$pkgdir/usr/share/licenses/${pkgname}/LICENSE-MIT"
+  install -Dm644 "UNLICENSE" "$pkgdir/usr/share/licenses/${pkgname}/UNLICENSE"
+}