[arch-commits] Commit in lib32-sqlite/repos (2 files)
Laurent Carlier
lcarlier at archlinux.org
Sat Apr 1 09:46:52 UTC 2017
Date: Saturday, April 1, 2017 @ 09:46:51
Author: lcarlier
Revision: 220280
archrelease: copy trunk to multilib-testing-x86_64
Added:
lib32-sqlite/repos/multilib-testing-x86_64/
lib32-sqlite/repos/multilib-testing-x86_64/PKGBUILD
(from rev 220279, lib32-sqlite/trunk/PKGBUILD)
----------+
PKGBUILD | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
Copied: lib32-sqlite/repos/multilib-testing-x86_64/PKGBUILD (from rev 220279, lib32-sqlite/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD (rev 0)
+++ multilib-testing-x86_64/PKGBUILD 2017-04-01 09:46:51 UTC (rev 220280)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Biru Ionut <ionut at archlinux.ro>
+# Contributor: Mikko Seppälä <t-r-a-y at mbnet.fi>
+# Contributor: Kaos < gianlucaatlas dot gmail dot com >
+
+_pkgbasename=sqlite
+pkgname=lib32-sqlite
+_srcver=3180000
+_docver=${_srcver}
+pkgver=3.18.0
+pkgrel=1
+pkgdesc="A C library that implements an SQL database engine (32-bit)"
+arch=('x86_64')
+license=('custom')
+url="http://www.sqlite.org/"
+depends=(lib32-glibc $_pkgbasename)
+makedepends=('tcl' 'gcc-multilib' 'lib32-readline')
+source=(https://www.sqlite.org/2017/sqlite-src-${_srcver}.zip)
+sha256sums=('eab4d137abd5aa1164244a5d558c9a02122071daf36984b236f8441d749b9ba6')
+options=('!makeflags')
+
+prepare() {
+ cd "$srcdir"/sqlite-src-$_srcver
+ autoreconf -vfi
+}
+
+build() {
+ cd "$srcdir"/sqlite-src-$_srcver
+
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+ export LTLINK_EXTRAS="-ldl"
+ export CFLAGS="$CFLAGS -DSQLITE_ENABLE_FTS3=1 \
+ -DSQLITE_ENABLE_COLUMN_METADATA=1 \
+ -DSQLITE_ENABLE_UNLOCK_NOTIFY \
+ -DSQLITE_ENABLE_DBSTAT_VTAB=1 \
+ -DSQLITE_ENABLE_FTS3_TOKENIZER=1 \
+ -DSQLITE_ENABLE_RTREE=1 \
+ -DSQLITE_SECURE_DELETE \
+ -DSQLITE_MAX_VARIABLE_NUMBER=250000"
+
+ ./configure --prefix=/usr \
+ --libdir=/usr/lib32 \
+ --disable-tcl \
+ --disable-static
+
+ make
+}
+
+package() {
+ cd "$srcdir"/sqlite-src-$_srcver
+
+ make DESTDIR=${pkgdir} install
+
+ rm -rf "${pkgdir}"/usr/{include,share,bin}
+ mkdir -p "$pkgdir/usr/share/licenses"
+ ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}
More information about the arch-commits
mailing list