[arch-commits] Commit in lib32-libdrm/repos (2 files)

[Laurent Carlier]

    Date: Tuesday, April 4, 2017 @ 15:42:06
  Author: lcarlier
Revision: 220484

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-libdrm/repos/multilib-testing-x86_64/
  lib32-libdrm/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 220483, lib32-libdrm/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: lib32-libdrm/repos/multilib-testing-x86_64/PKGBUILD (from rev 220483, lib32-libdrm/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2017-04-04 15:42:06 UTC (rev 220484)
@@ -0,0 +1,58 @@
+# $Id$
+# Maintainer: Laurent Carlier <lordheavym at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+_pkgbasename=libdrm
+pkgname=lib32-$_pkgbasename
+pkgver=2.4.77
+pkgrel=1
+pkgdesc="Userspace interface to kernel DRM services (32-bit)"
+arch=(x86_64)
+license=('custom')
+depends=('lib32-libpciaccess' $_pkgbasename)
+makedepends=(gcc-multilib xorg-util-macros valgrind-multilib)
+options=('!libtool')
+url="http://dri.freedesktop.org/"
+source=(https://dri.freedesktop.org/${_pkgbasename}/${_pkgbasename}-${pkgver}.tar.bz2{,.sig})
+sha256sums=('e8d5e2ca3a42a4d02b4df97fde45a12eeeb34c158008361026f82c8bf6fb3b6d'
+            'SKIP')
+validpgpkeys=('B97BD6A80CAC4981091AE547FE558C72A67013C3') # Maarten Lankhorst <maarten.lankhorst at canonical.com>
+validpgpkeys+=('215DEE688925CCB965BE5DA97C03D7797B6E1AE2') # Damien Lespiau <damien.lespiau at intel.com>
+validpgpkeys+=('10A6D91DA1B05BD29F6DEBAC0C74F35979C486BE') # David Airlie <airlied at redhat.com>
+validpgpkeys+=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov at gmail.com>
+validpgpkeys+=('D6285B5E899299F3DA746184191C9B905522B045') # Rob Clark <robclark at freedesktop.org>
+validpgpkeys+=('E8EB5B34081CE1EEA26EFE195B5BDA071D49CC38') # Kenneth Graunke <kenneth at whitecape.org>
+validpgpkeys+=('FC9BAE1435A9F7F664B82057B5D62936D1FC9EE8') # Eric Anholt <eric at anholt.net>
+validpgpkeys+=('3BB639E56F861FA2E86505690FDD682D974CA72A') # Matt Turner <mattst88 at gmail.com>
+validpgpkeys+=('C20F5C4490D7D64B4C9A09998CD1DF552975297B') # Robert Bragg <robert at sixbynine.org>
+validpgpkeys+=('CD47C5341A375F33BEF7BAFAFDD15D5ACEF0F2B1') # Marek Olšák <maraeo at gmail.com>
+
+build() {
+  cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./configure --prefix=/usr \
+     --libdir=/usr/lib32 \
+     --enable-udev
+
+  make
+}
+
+check() {
+  cd "${srcdir}/${_pkgbasename}-${pkgver}"
+  make -k check
+}
+
+package() {
+  cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+  make DESTDIR="${pkgdir}" install
+
+  rm -rf "${pkgdir}"/usr/{include,share,bin}
+  mkdir -p "$pkgdir/usr/share/licenses"
+  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}
+