[arch-commits] Commit in gnome-shell-extensions/repos (2 files)

[Jan de Groot]

    Date: Wednesday, April 12, 2017 @ 11:06:51
  Author: jgc
Revision: 292617

archrelease: copy trunk to gnome-unstable-any

Added:
  gnome-shell-extensions/repos/gnome-unstable-any/
  gnome-shell-extensions/repos/gnome-unstable-any/PKGBUILD
    (from rev 292616, gnome-shell-extensions/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: gnome-shell-extensions/repos/gnome-unstable-any/PKGBUILD (from rev 292616, gnome-shell-extensions/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-any/PKGBUILD	                        (rev 0)
+++ gnome-unstable-any/PKGBUILD	2017-04-12 11:06:51 UTC (rev 292617)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-shell-extensions
+pkgver=3.24.1+1+gfbf3cf3
+pkgrel=1
+pkgdesc="Extensions for GNOME shell, including classic mode"
+url="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
+arch=(any)
+license=(GPL)
+depends=(gnome-shell)
+makedepends=(intltool git gnome-common)
+optdepends=('nautilus: gnome-classic session')
+groups=(gnome)
+_commit=fbf3cf35a633d95f7f67ca28338d3202681f45f1  # master
+source=("git+https://git.gnome.org/browse/gnome-shell-extensions#commit=$_commit"
+        "git+https://git.gnome.org/browse/gnome-shell-sass")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.data/gnome-shell-sass.url "$srcdir/gnome-shell-sass"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --libexecdir=/usr/lib/gnome-session --enable-extensions=all
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}