[arch-commits] Commit in (4 files)

[Levente Polyak]

    Date: Friday, August 4, 2017 @ 14:51:20
  Author: anthraxx
Revision: 248444

upgpkg: python-editor 1.0.3-2

Added:
  python-editor/
  python-editor/repos/
  python-editor/trunk/
  python-editor/trunk/PKGBUILD

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Added: python-editor/trunk/PKGBUILD
===================================================================
--- python-editor/trunk/PKGBUILD	                        (rev 0)
+++ python-editor/trunk/PKGBUILD	2017-08-04 14:51:20 UTC (rev 248444)
@@ -0,0 +1,46 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Michael Straube <straubem at gmx.de>
+# Contributor: Kevin Brubeck Unhammer <unhammer at fsfe.org>
+
+pkgbase=python-editor
+pkgname=('python-editor' 'python2-editor')
+pkgver=1.0.3
+pkgrel=2
+pkgdesc='Programmatically open an editor, capture the result'
+url='https://github.com/fmoo/python-editor'
+arch=('any')
+license=('Apache')
+makedepends=('python-setuptools' 'python2-setuptools')
+source=(${pkgbase}-${pkgver}.tar.gz::https://github.com/fmoo/python-editor/archive/${pkgver}.tar.gz)
+sha256sums=('e627a2160bdf5e435dcde964cf38bae39c02cdd8da2ccf5fac313b2ca453e2a3')
+sha512sums=('0b14462099f8c5a3a7517f0f0cb744470284c34d164483bc58b15ecf4c5484090149d5dcb923b932a41857cfa34d4f10e4238ccc20089804a14631a459b63a39')
+
+prepare() {
+  cp -a ${pkgbase}-${pkgver}{,-py2}
+  sed 's|python|python2|' -i ${pkgbase}-${pkgver}-py2/editor.py
+}
+
+build() {
+  (cd ${pkgbase}-${pkgver}
+    python setup.py build
+  )
+  (cd ${pkgbase}-${pkgver}-py2
+    python2 setup.py build
+  )
+}
+
+package_python-editor() {
+  depends=('python')
+  cd ${pkgbase}-${pkgver}
+  python setup.py install --root="${pkgdir}" --skip-build
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+package_python2-editor() {
+  depends=('python2')
+  cd ${pkgbase}-${pkgver}-py2
+  python2 setup.py install --root="${pkgdir}" --skip-build
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: