[arch-commits] Commit in pandoc-citeproc/repos (2 files)

[Felix Yan]

    Date: Friday, December 1, 2017 @ 10:27:58
  Author: felixonmars
Revision: 270918

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc-citeproc/repos/community-staging-x86_64/
  pandoc-citeproc/repos/community-staging-x86_64/PKGBUILD
    (from rev 270917, pandoc-citeproc/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: pandoc-citeproc/repos/community-staging-x86_64/PKGBUILD (from rev 270917, pandoc-citeproc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2017-12-01 10:27:58 UTC (rev 270918)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc-citeproc
+pkgver=0.12.1
+pkgrel=18
+pkgdesc="Supports using pandoc with citeproc"
+url="https://hackage.haskell.org/package/$pkgname"
+license=("custom:BSD3")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-aeson" "haskell-aeson-pretty" "haskell-attoparsec" "haskell-data-default"
+         "haskell-hs-bibutils" "haskell-mtl" "haskell-old-locale" "pandoc" "haskell-pandoc-types"
+         "haskell-parsec" "haskell-rfc5051" "haskell-setenv" "haskell-split" "haskell-syb"
+         "haskell-tagsoup" "haskell-temporary" "haskell-text" "haskell-text-icu"
+         "haskell-unordered-containers" "haskell-vector" "haskell-xml-conduit" "haskell-yaml")
+conflicts=('haskell-pandoc-citeproc')
+replaces=('haskell-pandoc-citeproc')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/$pkgname/${pkgver}/$pkgname-${pkgver}.tar.gz")
+sha512sums=('74ab07cc8a62523079195c6b9e2283b992ef496782d58c9e4ee84f4343f6d69f1f4229eab27b594c5bf0d52536976fb42f1c9848d034dff7034d27d334492b06')
+
+build() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/$pkgname" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-debug -f-test_citeproc -funicode_collation -f-embed_data_files -fbibutils -f-static
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/$pkgname.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/$pkgname.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/$pkgname/LICENSE"
+}