[arch-commits] Commit in gst-plugins-bad/repos (2 files)

[Maxime Gauduin]

    Date: Friday, December 8, 2017 @ 13:07:34
  Author: alucryd
Revision: 311927

archrelease: copy trunk to staging-x86_64

Added:
  gst-plugins-bad/repos/staging-x86_64/
  gst-plugins-bad/repos/staging-x86_64/PKGBUILD
    (from rev 311926, gst-plugins-bad/trunk/PKGBUILD)

----------+
 PKGBUILD |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

Copied: gst-plugins-bad/repos/staging-x86_64/PKGBUILD (from rev 311926, gst-plugins-bad/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2017-12-08 13:07:34 UTC (rev 311927)
@@ -0,0 +1,69 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gst-plugins-bad
+pkgver=1.12.3
+pkgrel=2
+pkgdesc="GStreamer Multimedia Framework Bad Plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(mjpegtools gst-plugins-base-libs curl chromaprint libmms faad2 celt libdca libdvdnav
+         libmodplug libgme wayland libofa openjpeg2 libwebp libsrtp gnutls glu sbc rtmpdump
+         libgudev graphene schroedinger libexif libdvdread libvdpau libmpeg2 wildmidi ladspa
+         openal libusb vulkan-icd-loader libfdk-aac faac soundtouch spandsp neon
+         webrtc-audio-processing libdc1394 libmpcdec zvbi)
+makedepends=(python valgrind gobject-introspection gtk-doc git autoconf-archive vulkan-headers
+             gtk3 clutter librsvg libtiger qt5-declarative qt5-x11extras qt5-wayland zbar
+             fluidsynth lilv opencv openexr)
+_commit=8f66ff25f9cabc170c57d75a74984103c7fcb965  # tags/1.12.3^0
+source=("git+https://anongit.freedesktop.org/git/gstreamer/gst-plugins-bad#commit=$_commit"
+        "gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git cherry-pick -n ef4d6b93e6078b7056c51a928f5620b13e55e323
+
+  git submodule init
+  git config --local submodule.common.url "$srcdir/gst-common"
+  git submodule update
+
+  sed -i 's/cmu_us_kal/&16/g' configure.ac ext/flite/gstflitetestsrc.c
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
+    --with-package-name="GStreamer Bad Plugins (Arch Linux)" \
+    --with-package-origin="https://www.archlinux.org/" \
+    --with-gtk=3.0 \
+    --enable-experimental --enable-gtk-doc --disable-static
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  cd $pkgname
+  # bad tests are bad
+  #make -k check || :
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}