[arch-commits] Commit in pygobject2/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Sunday, December 10, 2017 @ 16:49:20
  Author: heftig
Revision: 312068

archrelease: copy trunk to extra-x86_64

Added:
  pygobject2/repos/extra-x86_64/PKGBUILD
    (from rev 312067, pygobject2/trunk/PKGBUILD)
Deleted:
  pygobject2/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  144 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 70 insertions(+), 74 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2017-12-10 16:48:36 UTC (rev 312067)
+++ PKGBUILD	2017-12-10 16:49:20 UTC (rev 312068)
@@ -1,74 +0,0 @@
-# $Id$
-# Maintainer: Jan de Groot <jgc at archlinux.org>
-
-pkgbase=pygobject2
-pkgname=(python-gobject2 python2-gobject2 pygobject2-devel)
-pkgver=2.28.6
-pkgrel=13
-arch=(i686 x86_64)
-url="http://www.pygtk.org/"
-license=(LGPL)
-makedepends=(python python2 git)
-
-# pygobject-2-28 branch: https://git.gnome.org/browse/pygobject/log/?h=pygobject-2-28
-source=('git://git.gnome.org/pygobject#commit=9456ba7')
-sha256sums=('SKIP')
-
-prepare() {
-  cd pygobject
-  autoreconf -fi
-
-  cp -a . ../python2-build
-
-  find -O3 ../python2-build \
-    \( -name '*.py' -o -name '*.py.in' \) \
-    -exec sed -i '1s|python$|&2|' {} +
-}
-
-build() {
-  cd python2-build
-  ./configure --prefix=/usr --disable-introspection \
-    PYTHON=/usr/bin/python2
-  make
-
-  cd ../pygobject
-  ./configure --prefix=/usr --disable-introspection
-  make
-}
-
-package_python-gobject2() {
-  pkgdesc="Python 3 bindings for GObject2"
-  depends=(glib2 pygobject2-devel python)
-  replaces=(py3gobject)
-  provides=("py3gobject=$pkgver")
-
-  cd pygobject
-  make DESTDIR="$pkgdir" install
-
-  # Delete devel stuff
-  rm -r "$pkgdir"/usr/{include,lib/pkgconfig,share/{gtk-doc,pygobject/xsl}}
-}
-
-package_python2-gobject2() {
-  pkgdesc="Python 2 bindings for GObject2"
-  depends=(glib2 pygobject2-devel python2)
-  replaces=(pygobject)
-  provides=("pygobject=$pkgver")
-
-  cd python2-build
-  make DESTDIR="$pkgdir" install
-
-  rm -r "$pkgdir"/usr/share/gtk-doc
-
-  # Split devel stuff
-  cd ..
-  mkdir -p devel/usr/{lib,share/pygobject}
-  mv {"$pkgdir",devel}/usr/include
-  mv {"$pkgdir",devel}/usr/lib/pkgconfig
-  mv {"$pkgdir",devel}/usr/share/pygobject/xsl
-}
-
-package_pygobject2-devel() {
-  pkgdesc="Development files for the pygobject bindings"
-  mv devel/* "$pkgdir"
-}

Copied: pygobject2/repos/extra-x86_64/PKGBUILD (from rev 312067, pygobject2/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2017-12-10 16:49:20 UTC (rev 312068)
@@ -0,0 +1,70 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=pygobject2
+pkgname=(python-gobject2 python2-gobject2 pygobject2-devel)
+pkgver=2.28.7
+pkgrel=1
+pkgdesc="Python bindings for GObject (legacy)"
+url="http://www.pygtk.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(glib2)
+makedepends=(python python2 git)
+options=(!emptydirs)
+_commit=c9594b6a91e6ca2086fedec2ed8249e0a9c029fc  # tags/PYGOBJECT_2_28_7^0
+source=("git+https://git.gnome.org/browse/pygobject#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd pygobject
+  git describe --tags | sed 's/^PYGOBJECT_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  mkdir build-py{2,3} devel
+  cd pygobject
+  find . \( -name '*.py' -o -name '*.py.in' \) -exec sed -i '1s|python$|&2|' {} +
+  autoreconf -fvi
+}
+
+_build() (
+  cd build-py$1
+  ../pygobject/configure --prefix=/usr --disable-introspection PYTHON=/usr/bin/python$1
+  sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+)
+
+build() {
+  _build 2
+  _build 3
+}
+
+package_python-gobject2() {
+  depends=("pygobject2-devel=$pkgver" python)
+
+  cd build-py3
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir"/usr/{include,lib/pkgconfig,share/pygobject/xsl}
+  rm -r "$pkgdir"/usr/share/gtk-doc
+}
+
+package_python2-gobject2() {
+  pkgdesc="${pkgdesc/Python/Python2}"
+  depends=("pygobject2-devel=$pkgver" python2)
+
+  cd build-py2
+  make DESTDIR="$pkgdir" install
+  mv "$pkgdir"/usr/{include,lib/pkgconfig,share/pygobject/xsl} "$srcdir/devel"
+  rm -r "$pkgdir"/usr/share/gtk-doc
+}
+
+package_pygobject2-devel() {
+  pkgdesc="Common development files for pygobject2"
+
+  cd devel
+  mkdir -p "$pkgdir"/usr/{lib,share/pygobject}
+  mv include "$pkgdir/usr/"
+  mv pkgconfig "$pkgdir/usr/lib/"
+  mv xsl "$pkgdir/usr/share/pygobject/"
+}