[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, December 11, 2017 @ 17:43:19
  Author: felixonmars
Revision: 273771

addpkg: haskell-typed-process 0.2.0.0-1

Added:
  haskell-typed-process/
  haskell-typed-process/repos/
  haskell-typed-process/trunk/
  haskell-typed-process/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: haskell-typed-process/trunk/PKGBUILD
===================================================================
--- haskell-typed-process/trunk/PKGBUILD	                        (rev 0)
+++ haskell-typed-process/trunk/PKGBUILD	2017-12-11 17:43:19 UTC (rev 273771)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=typed-process
+pkgname=haskell-typed-process
+pkgver=0.2.0.0
+pkgrel=1
+pkgdesc="Run external processes, with strong typing of streams"
+url="https://haskell-lang.org/library/typed-process"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-stm')
+makedepends=('ghc' 'haskell-base64-bytestring' 'haskell-hspec' 'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('c48efb8cd7d3d7612ad38a1ce5339adf94507e1d8ee50184ff5953973cbc13fd22fba15d27ce75836ba4e9189f30c2b68e67ee0ada86b56c658d9dec79b9b127')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


Property changes on: haskell-typed-process/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property