[arch-commits] Commit in haskell-http-conduit/repos (2 files)

[Felix Yan]

    Date: Monday, December 11, 2017 @ 18:00:18
  Author: felixonmars
Revision: 273790

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-conduit/repos/community-staging-x86_64/
  haskell-http-conduit/repos/community-staging-x86_64/PKGBUILD
    (from rev 273789, haskell-http-conduit/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-http-conduit/repos/community-staging-x86_64/PKGBUILD (from rev 273789, haskell-http-conduit/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2017-12-11 18:00:18 UTC (rev 273790)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http-conduit
+pkgname=haskell-http-conduit
+pkgver=2.2.4
+pkgrel=2
+pkgdesc="HTTP client package with conduit interface and HTTPS support"
+url="http://www.yesodweb.com/book/http-conduit"
+license=("custom:BSD3")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-conduit' 'haskell-conduit-extra' 'haskell-exceptions'
+         'haskell-http-client' 'haskell-http-client-tls' 'haskell-http-types' 'haskell-lifted-base'
+         'haskell-monad-control' 'haskell-mtl' 'haskell-resourcet')
+makedepends=('ghc' 'haskell-blaze-builder' 'haskell-case-insensitive' 'haskell-connection'
+             'haskell-cookie' 'haskell-data-default-class' 'haskell-hunit' 'haskell-hspec'
+             'haskell-lifted-base' 'haskell-network' 'haskell-streaming-commons' 'haskell-temporary'
+             'haskell-text' 'haskell-utf8-string' 'haskell-wai' 'haskell-wai-conduit' 'haskell-warp'
+             'haskell-warp-tls')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('67106bac629e82b271b9c692ef115962775bc605385b008bc1c7453204c20039ab6157b3db2ca707383b877f1e1c63750a3a28bd1ae566fadc0b4e07922f5b63')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}