[arch-commits] Commit in facter/repos (2 files)

[Jonathan Steel]

    Date: Wednesday, December 13, 2017 @ 12:46:53
  Author: jsteel
Revision: 274210

archrelease: copy trunk to community-testing-x86_64

Added:
  facter/repos/community-testing-x86_64/
  facter/repos/community-testing-x86_64/PKGBUILD
    (from rev 274208, facter/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: facter/repos/community-testing-x86_64/PKGBUILD (from rev 274208, facter/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2017-12-13 12:46:53 UTC (rev 274210)
@@ -0,0 +1,46 @@
+# $Id$
+# Maintainer: Jonathan Steel <jsteel at archlinux.org>
+# Contributor: Greg Sutcliffe <facter_aur (at) emeraldreverie.orgr>
+# Contributor: Hyacinthe Cartiaux <hyacinthe.cartiaux at free.fr>
+# Contributor: Thomas S Hatch <thatch45 (at) Gmail.com>
+# Contributor: Dave Simons <miouhpi (at) Gmail (dot) com>
+# Contributor: Niels Abspoel <aboe76 (at) Gmail (dot) com>
+
+pkgname=facter
+pkgver=3.9.3
+pkgrel=1
+pkgdesc="Collect and display system facts"
+arch=('x86_64')
+url="http://puppetlabs.com/facter"
+license=('APACHE')
+depends=('ruby' 'yaml-cpp' 'boost-libs' 'curl')
+makedepends=('boost' 'cmake' 'java-environment' 'leatherman' 'cpp-hocon')
+optdepends=('java-environment: jruby support')
+replaces=('cfacter')
+source=(http://downloads.puppetlabs.com/$pkgname/$pkgname-$pkgver.tar.gz)
+md5sums=('4b4607f2f8d9d694810d5cfe76fbcd7e')
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  # Replace rb_data_object_alloc symbol with rb_data_object_wrap
+  # https://tickets.puppetlabs.com/browse/FACT-1291
+  sed -i 's/rb_data_object_alloc/rb_data_object_wrap/g' \
+    $( grep -rl rb_data_object_alloc lib/src/ruby )
+}
+
+build() {
+  cd $pkgname-$pkgver
+
+  JAVA_HOME=/usr/lib/jvm/default cmake -DCMAKE_INSTALL_PREFIX=/usr
+
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+
+  make install DESTDIR="$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}