[arch-commits] Commit in libxkbcommon/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Saturday, December 16, 2017 @ 22:04:13
  Author: heftig
Revision: 312980

archrelease: copy trunk to extra-x86_64

Added:
  libxkbcommon/repos/extra-x86_64/PKGBUILD
    (from rev 312979, libxkbcommon/trunk/PKGBUILD)
Deleted:
  libxkbcommon/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  138 ++++++++++++++++++++++++++++++++++---------------------------
 1 file changed, 77 insertions(+), 61 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2017-12-16 22:02:54 UTC (rev 312979)
+++ PKGBUILD	2017-12-16 22:04:13 UTC (rev 312980)
@@ -1,61 +0,0 @@
-# $Id$
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Contributor: Daniel Micay <danielmicay at gmail.com>
-# Contributor: Mladen Pejakovic <pejakm at gmail.com>
-
-pkgbase=libxkbcommon
-pkgname=(libxkbcommon libxkbcommon-x11)
-pkgver=0.7.2
-pkgrel=1
-pkgdesc="Keymap handling library for toolkits and window systems"
-arch=(i686 x86_64)
-url="https://xkbcommon.org/"
-license=(custom)
-depends=(xkeyboard-config glibc)
-checkdepends=(xorg-server-xvfb libgl)
-makedepends=(libxcb doxygen git graphviz wayland wayland-protocols meson)
-_commit=ba9568bdb128f3c5f717b8503439ef6e50a66e97  # tags/xkbcommon-0.7.2^0
-source=("git+https://github.com/xkbcommon/libxkbcommon#commit=$_commit")
-md5sums=('SKIP')
-
-pkgver() {
-  cd $pkgbase
-  git describe --tags | sed 's/^xkbcommon-//;s/-/+/g'
-}
-
-prepare() {
-  mkdir -p build x11/usr/{include/xkbcommon,lib/pkgconfig}
-  cd $pkgbase
-}
-
-build() {
-  cd build
-  meson --prefix=/usr --buildtype=release ../$pkgbase
-  ninja
-}
-
-check() {
-  cd build
-  xvfb-run -a mesontest
-}
-
-package_libxkbcommon() {
-  cd build
-  DESTDIR="$pkgdir" ninja install
-  install -Dm644 ../$pkgbase/LICENSE "$pkgdir/usr/share/licenses/libxkbcommon/LICENSE"
-
-### Split libxkbcommon-x11
-
-  mv "$pkgdir"/usr/lib/*x11* "$srcdir/x11/usr/lib"
-  mv "$pkgdir"/usr/lib/pkgconfig/*x11* "$srcdir/x11/usr/lib/pkgconfig"
-  mv "$pkgdir"/usr/include/xkbcommon/*x11* "$srcdir/x11/usr/include/xkbcommon"
-}
-
-package_libxkbcommon-x11() {
-  pkgdesc="Keyboard handling library using XKB data for X11 XCB clients"
-  depends=(libxkbcommon libxcb)
-
-  mv x11/* "$pkgdir"
-
-  install -Dm644 $pkgbase/LICENSE "$pkgdir/usr/share/licenses/libxkbcommon-x11/LICENSE"
-}

Copied: libxkbcommon/repos/extra-x86_64/PKGBUILD (from rev 312979, libxkbcommon/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2017-12-16 22:04:13 UTC (rev 312980)
@@ -0,0 +1,77 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+# Contributor: Mladen Pejakovic <pejakm at gmail.com>
+
+pkgbase=libxkbcommon
+pkgname=(libxkbcommon libxkbcommon-doc libxkbcommon-x11)
+pkgver=0.8.0
+pkgrel=1
+pkgdesc="Keymap handling library for toolkits and window systems"
+arch=(x86_64)
+url="https://xkbcommon.org/"
+license=(custom)
+depends=(xkeyboard-config glibc)
+checkdepends=(xorg-server-xvfb libgl)
+makedepends=(libxcb doxygen git graphviz wayland wayland-protocols meson)
+_commit=b82e3b764e60df337ca695e8f8642e7bf42b0cca  # tags/xkbcommon-0.8.0^0
+source=("git+https://github.com/xkbcommon/libxkbcommon#commit=$_commit")
+md5sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/^xkbcommon-//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+  printf '%s\n' >>doc/Doxyfile.in \
+    HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
+}
+
+build() {
+  arch-meson $pkgbase build
+  ninja -C build
+}
+
+check() {
+  cd build
+  xvfb-run -a meson test
+}
+
+package_libxkbcommon() {
+  DESTDIR="$pkgdir" ninja -C build install
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgbase/LICENSE
+
+### Split libxkbcommon-doc
+
+  mkdir -p "$srcdir"/doc/usr/share
+  mv "$pkgdir"/usr/share/doc "$srcdir/doc/usr/share"
+
+### Split libxkbcommon-x11
+
+  mkdir -p "$srcdir"/x11/usr/{include/xkbcommon,lib/pkgconfig}
+  mv "$pkgdir"/usr/lib/*x11* "$srcdir/x11/usr/lib"
+  mv "$pkgdir"/usr/lib/pkgconfig/*x11* "$srcdir/x11/usr/lib/pkgconfig"
+  mv "$pkgdir"/usr/include/xkbcommon/*x11* "$srcdir/x11/usr/include/xkbcommon"
+}
+
+package_libxkbcommon-doc() {
+  pkgdesc="API documentation for libxkbcommon"
+  depends=(libxkbcommon)
+
+  mv doc/* "$pkgdir"
+
+  install -d "$pkgdir/usr/share/licenses"
+  ln -s libxkbcommon "$pkgdir/usr/share/licenses/$pkgname"
+}
+
+package_libxkbcommon-x11() {
+  pkgdesc="Keyboard handling library using XKB data for X11 XCB clients"
+  depends=(libxkbcommon libxcb)
+
+  mv x11/* "$pkgdir"
+
+  install -d "$pkgdir/usr/share/licenses"
+  ln -s libxkbcommon "$pkgdir/usr/share/licenses/$pkgname"
+}