[arch-commits] Commit in mkvtoolnix/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Maxime Gauduin]

    Date: Tuesday, December 19, 2017 @ 20:31:00
  Author: alucryd
Revision: 313368

archrelease: copy trunk to extra-x86_64

Added:
  mkvtoolnix/repos/extra-x86_64/PKGBUILD
    (from rev 313367, mkvtoolnix/trunk/PKGBUILD)
Deleted:
  mkvtoolnix/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  124 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 62 insertions(+), 62 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2017-12-19 20:29:23 UTC (rev 313367)
+++ PKGBUILD	2017-12-19 20:31:00 UTC (rev 313368)
@@ -1,62 +0,0 @@
-# $Id$
-# Maintainer: Giovanni Scafora <giovanni at archlinux.org>
-# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
-# Contributor: xduugu <xduugu at gmx.com>
-
-pkgbase=mkvtoolnix
-pkgname=('mkvtoolnix-cli' 'mkvtoolnix-gui')
-pkgver=18.0.0
-pkgrel=1
-pkgdesc='Set of tools to create, edit and inspect Matroska files'
-arch=('x86_64')
-url='https://www.bunkus.org/videotools/mkvtoolnix/'
-license=('GPL')
-makedepends=('boost' 'boost-libs' 'docbook-xsl' 'file' 'flac' 'libebml'
-             'libmatroska' 'libogg' 'libvorbis' 'qt5-multimedia' 'ruby' 'zlib')
-source=("http://www.bunkus.org/videotools/mkvtoolnix/sources/mkvtoolnix-${pkgver}.tar.xz")
-sha256sums=('b8282d6d279caa86038721d2a49471d1dd25a465ee1a779ee9c2a99bc8ff972f')
-
-build() {
-  cd mkvtoolnix-${pkgver}
-
-  ./configure \
-    --prefix='/usr' \
-    --disable-qt
-  rake apps:mkvinfo $MAKEFLAGS
-  mv src/mkvinfo{,-cli}
-
-  ./configure \
-    --prefix='/usr' \
-    --disable-update-check
-  rake $MAKEFLAGS
-}
-
-package_mkvtoolnix-cli() {
-  depends=('boost-libs' 'file' 'flac' 'gcc-libs' 'glibc' 'libogg' 'zlib'
-           'libebml.so' 'libmatroska.so' 'libvorbis.so')
-
-  cd mkvtoolnix-${pkgver}
-
-  rake DESTDIR="${pkgdir}" install
-  install -m 755 src/mkvinfo-cli "${pkgdir}"/usr/bin/mkvinfo
-  rm -rf "${pkgdir}"/usr/share/{applications,icons,mime,mkvtoolnix}
-  find "${pkgdir}" -name mkvtoolnix-gui* -delete
-}
-
-package_mkvtoolnix-gui() {
-  depends=('desktop-file-utils' 'hicolor-icon-theme' 'mkvtoolnix-cli'
-           'qt5-multimedia' 'shared-mime-info' 'xdg-utils')
-  replaces=('mkvtoolnix-gtk')
-
-  cd mkvtoolnix-${pkgver}
-
-  rake DESTDIR="${pkgdir}" install
-  rm -rf "${pkgdir}"/usr/share/locale
-  for t in mkv{extract,info,merge,propedit}; do
-    find "${pkgdir}" -name $t* -delete
-  done
-  # The GUI is disabled in our mkvinfo
-  rm "${pkgdir}"/usr/share/applications/org.bunkus.mkvinfo.desktop
-}
-
-# vim: ts=2 sw=2 et:

Copied: mkvtoolnix/repos/extra-x86_64/PKGBUILD (from rev 313367, mkvtoolnix/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2017-12-19 20:31:00 UTC (rev 313368)
@@ -0,0 +1,62 @@
+# $Id$
+# Maintainer: Giovanni Scafora <giovanni at archlinux.org>
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: xduugu <xduugu at gmx.com>
+
+pkgbase=mkvtoolnix
+pkgname=('mkvtoolnix-cli' 'mkvtoolnix-gui')
+pkgver=19.0.0
+pkgrel=1
+pkgdesc='Set of tools to create, edit and inspect Matroska files'
+arch=('x86_64')
+url='https://www.bunkus.org/videotools/mkvtoolnix/'
+license=('GPL')
+makedepends=('boost' 'boost-libs' 'docbook-xsl' 'file' 'flac' 'libebml'
+             'libmatroska' 'libogg' 'libvorbis' 'qt5-multimedia' 'ruby' 'zlib')
+source=("http://www.bunkus.org/videotools/mkvtoolnix/sources/mkvtoolnix-${pkgver}.tar.xz")
+sha256sums=('4b4af84cfdf3062f8ca4ab3c37854be7cd9a71bcf5c46b8ca805a101d414b6a1')
+
+build() {
+  cd mkvtoolnix-${pkgver}
+
+  ./configure \
+    --prefix='/usr' \
+    --disable-qt
+  rake apps:mkvinfo $MAKEFLAGS
+  mv src/mkvinfo{,-cli}
+
+  ./configure \
+    --prefix='/usr' \
+    --disable-update-check
+  rake $MAKEFLAGS
+}
+
+package_mkvtoolnix-cli() {
+  depends=('boost-libs' 'file' 'flac' 'gcc-libs' 'glibc' 'libogg' 'zlib'
+           'libebml.so' 'libmatroska.so' 'libvorbis.so')
+
+  cd mkvtoolnix-${pkgver}
+
+  rake DESTDIR="${pkgdir}" install
+  install -m 755 src/mkvinfo-cli "${pkgdir}"/usr/bin/mkvinfo
+  rm -rf "${pkgdir}"/usr/share/{applications,icons,mime,mkvtoolnix}
+  find "${pkgdir}" -name mkvtoolnix-gui* -delete
+}
+
+package_mkvtoolnix-gui() {
+  depends=('desktop-file-utils' 'hicolor-icon-theme' 'mkvtoolnix-cli'
+           'qt5-multimedia' 'shared-mime-info' 'xdg-utils')
+  replaces=('mkvtoolnix-gtk')
+
+  cd mkvtoolnix-${pkgver}
+
+  rake DESTDIR="${pkgdir}" install
+  rm -rf "${pkgdir}"/usr/share/locale
+  for t in mkv{extract,info,merge,propedit}; do
+    find "${pkgdir}" -name $t* -delete
+  done
+  # The GUI is disabled in our mkvinfo
+  rm "${pkgdir}"/usr/share/applications/org.bunkus.mkvinfo.desktop
+}
+
+# vim: ts=2 sw=2 et: