[arch-commits] Commit in openmpi/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Levente Polyak
anthraxx at archlinux.org
Wed Dec 20 09:30:18 UTC 2017
Date: Wednesday, December 20, 2017 @ 09:30:17
Author: anthraxx
Revision: 313381
archrelease: copy trunk to staging-x86_64
Added:
openmpi/repos/staging-x86_64/
openmpi/repos/staging-x86_64/PKGBUILD
(from rev 313380, openmpi/trunk/PKGBUILD)
----------+
PKGBUILD | 62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 62 insertions(+)
Copied: openmpi/repos/staging-x86_64/PKGBUILD (from rev 313380, openmpi/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2017-12-20 09:30:17 UTC (rev 313381)
@@ -0,0 +1,62 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Anatol Pomozov <anatol dot pomozov at gmail>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+
+pkgname=openmpi
+pkgver=3.0.0
+pkgrel=1
+pkgdesc='High performance message passing library (MPI)'
+url='https://www.open-mpi.org'
+arch=('x86_64')
+license=('custom:OpenMPI')
+depends=('libltdl' 'hwloc' 'openssh')
+makedepends=('inetutils' 'valgrind' 'gcc-fortran')
+optdepends=('gcc-fortran: fortran support')
+options=('staticlibs')
+source=(https://www.open-mpi.org/software/ompi/v${pkgver%.*}/downloads/${pkgname}-${pkgver}.tar.bz2)
+sha256sums=('f699bff21db0125d8cccfe79518b77641cd83628725a1e1ed3e45633496a82d7')
+sha512sums=('7e37eacf959a803d6d89dff4291b64a1f3d83bc7941b778a2fb13d12be0f205cb904e4a807d79676ad1e31fd99ffb15f255c8a227e830673455abb144f14616a')
+
+build() {
+ cd ${pkgname}-${pkgver}
+ ./configure --prefix=/usr \
+ --sysconfdir=/etc/${pkgname} \
+ --enable-mpi-fortran=all \
+ --libdir=/usr/lib/${pkgname} \
+ --with-threads=posix \
+ --enable-mpi-thread-multiple \
+ --enable-smp-locks \
+ --enable-builtin-atomics \
+ --enable-mpi-cxx \
+ --with-valgrind \
+ --enable-memchecker \
+ --enable-pretty-print-stacktrace \
+ --without-slurm \
+ --with-hwloc=/usr \
+ --with-libltdl=/usr \
+ FC=/usr/bin/gfortran \
+ LDFLAGS="${LDFLAGS} -Wl,-z,noexecstack"
+ make
+}
+
+check() {
+ cd ${pkgname}-${pkgver}
+ make check
+}
+
+package() {
+ cd ${pkgname}-${pkgver}
+ make DESTDIR="${pkgdir}" install
+
+ # FS#28583
+ install -dm 755 "${pkgdir}/usr/lib/pkgconfig"
+ for i in ompi-c.pc ompi-cxx.pc ompi-f77.pc ompi-f90.pc ompi.pc; do
+ ln -sf "/usr/lib/openmpi/pkgconfig/${i}" "${pkgdir}/usr/lib/pkgconfig/"
+ done
+
+ install -dm 755 "${pkgdir}/etc/ld.so.conf.d"
+ echo "/usr/lib/${pkgname}" > "${pkgdir}"/etc/ld.so.conf.d/${pkgname}.conf
+ install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list