[arch-commits] Commit in librsvg/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan de Groot]

    Date: Thursday, December 21, 2017 @ 09:23:22
  Author: jgc
Revision: 313475

archrelease: copy trunk to testing-x86_64

Added:
  librsvg/repos/testing-x86_64/
  librsvg/repos/testing-x86_64/PKGBUILD
    (from rev 313474, librsvg/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: librsvg/repos/testing-x86_64/PKGBUILD (from rev 313474, librsvg/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2017-12-21 09:23:22 UTC (rev 313475)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=librsvg
+pkgver=2.41.2
+pkgrel=1
+epoch=2
+pkgdesc="SVG rendering library"
+url="https://wiki.gnome.org/Projects/LibRsvg"
+arch=(x86_64)
+license=(LGPL)
+depends=(gdk-pixbuf2 pango libcroco)
+makedepends=(intltool gobject-introspection vala python2 gtk-doc git rust)
+_commit=f822e90c7a91f12c76793ffe8e349584d4d813f8  # tags/2.41.2^0
+source=("git+https://git.gnome.org/browse/librsvg#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --disable-static --enable-vala --enable-gtk-doc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  # Reftests fail due to differences in text rendering
+  # Even with the fixated font on master there are still differences on i686
+  make check || :
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}