[arch-commits] Commit in python-mpi4py/repos (2 files)

[Bruno Pagani]

    Date: Thursday, December 21, 2017 @ 10:42:37
  Author: archange
Revision: 275160

archrelease: copy trunk to community-staging-x86_64

Added:
  python-mpi4py/repos/community-staging-x86_64/
  python-mpi4py/repos/community-staging-x86_64/PKGBUILD
    (from rev 275159, python-mpi4py/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: python-mpi4py/repos/community-staging-x86_64/PKGBUILD (from rev 275159, python-mpi4py/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2017-12-21 10:42:37 UTC (rev 275160)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Anatol Pomozov
+# Contributor: Tim Hütz <tim at huetz.biz>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Sebastien Binet <binet at cern.ch>
+
+_pkg=mpi4py
+pkgbase=python-${_pkg}
+pkgname=(python-${_pkg} python2-${_pkg})
+pkgver=3.0.0
+pkgrel=2
+pkgdesc="Python bindings for the Message Passing Interface (MPI) standard"
+arch=(x86_64)
+url="https://bitbucket.org/mpi4py/mpi4py"
+license=(BSD)
+makedepends=(python-setuptools python2-setuptools openmpi)
+checkdepends=(inetutils)
+source=("https://pypi.io/packages/source/m/${_pkg}/${_pkg}-${pkgver}.tar.gz")
+sha256sums=(b457b02d85bdd9a4775a097fac5234a20397b43e073f14d9e29b6cd78c68efd7)
+
+prepare() {
+    cp -a ${_pkg}-${pkgver}{,-py2}
+}
+
+build() {
+    cd ${_pkg}-${pkgver}
+    python setup.py build
+
+    cd ../${_pkg}-${pkgver}-py2
+    python2 setup.py build
+}
+
+check() {
+    # This is required starting with OpenMPI 3.0 when trying to run more
+    # processes than the number of available cores
+    export OMPI_MCA_rmaps_base_oversubscribe=yes
+
+    cd ${_pkg}-${pkgver}
+    python setup.py test
+
+    cd ../${_pkg}-${pkgver}-py2
+    python2 setup.py test
+}
+
+package_python-mpi4py() {
+    depends=(python openmpi)
+
+    cd ${_pkg}-${pkgver}
+    python setup.py install --root="${pkgdir}" --skip-build --optimize=1
+    install -Dm644 LICENSE.rst -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}
+
+package_python2-mpi4py() {
+    depends=(python2 openmpi)
+
+    cd ${_pkg}-${pkgver}-py2
+    python2 setup.py install --root="$pkgdir" --skip-build --optimize=1
+    install -Dm644 LICENSE.rst -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}