[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, December 28, 2017 @ 09:42:01
  Author: felixonmars
Revision: 276391

addpkg: haskell-quickcheck-unicode 1.0.1.0-1

Added:
  haskell-quickcheck-unicode/
  haskell-quickcheck-unicode/repos/
  haskell-quickcheck-unicode/trunk/
  haskell-quickcheck-unicode/trunk/PKGBUILD

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Added: haskell-quickcheck-unicode/trunk/PKGBUILD
===================================================================
--- haskell-quickcheck-unicode/trunk/PKGBUILD	                        (rev 0)
+++ haskell-quickcheck-unicode/trunk/PKGBUILD	2017-12-28 09:42:01 UTC (rev 276391)
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=quickcheck-unicode
+pkgname=haskell-quickcheck-unicode
+pkgver=1.0.1.0
+pkgrel=1
+pkgdesc="Generator and shrink functions for testing Unicode-related software."
+url="https://github.com/bos/quickcheck-unicode"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('4762d9cdf7624e28586ed18ad05f273b600bf664cb3f3f76d9e33dd217181f49f5835ac6276da8d5302dbf89fe65cec4e9d3c1e57dfc457ee3b3748467672c15')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


Property changes on: haskell-quickcheck-unicode/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property