[arch-commits] Commit in blender/repos (3 files)
Sven-Hendrik Haase
svenstaro at archlinux.org
Fri Dec 29 02:59:24 UTC 2017
Date: Friday, December 29, 2017 @ 02:59:24
Author: svenstaro
Revision: 276776
archrelease: copy trunk to community-staging-x86_64
Added:
blender/repos/community-staging-x86_64/
blender/repos/community-staging-x86_64/PKGBUILD
(from rev 276775, blender/trunk/PKGBUILD)
blender/repos/community-staging-x86_64/cuda9.patch
(from rev 276775, blender/trunk/cuda9.patch)
-------------+
PKGBUILD | 109 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
cuda9.patch | 40 +++++++++++++++++++++
2 files changed, 149 insertions(+)
Copied: blender/repos/community-staging-x86_64/PKGBUILD (from rev 276775, blender/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2017-12-29 02:59:24 UTC (rev 276776)
@@ -0,0 +1,109 @@
+# $Id$
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: John Sowiak <john at archlinux.org>
+# Contributor: tobias <tobias at archlinux.org>
+
+# Sometimes blender.org takes some time to release patch releases and because Arch users
+# are impatient, we sometimes need to build from git directly.
+# Update because I get so many queries on this:
+# Due to our other rolling deps, it's sometimes not possible to build Blender stable releases.
+# More often than not, a new openshadinglanguage breaks it and I could either backport fixes
+# or simply roll with a new version. I usually choose the latter when the former seems
+# unreasonable.
+
+ _gittag=v2.79
+#_gitcommit=3c3d0898b0c1a1d7da70f4a1778d4360b3cfe5c8
+
+pkgname=blender
+pkgver=2.79
+#[[ -n $_gitcommit ]] && pkgver=${pkgver}.git1.${_gitcommit}
+pkgrel=8
+epoch=17
+pkgdesc="A fully integrated 3D graphics creation suite"
+arch=('x86_64')
+license=('GPL')
+url="http://www.blender.org"
+depends=('libpng' 'libtiff' 'openexr' 'python' 'desktop-file-utils' 'python-requests'
+ 'shared-mime-info' 'hicolor-icon-theme' 'xdg-utils' 'glew' 'openjpeg' 'python-numpy'
+ 'freetype2' 'openal' 'ffmpeg' 'fftw' 'boost-libs' 'opencollada' 'alembic'
+ 'openimageio' 'libsndfile' 'jack' 'opencolorio' 'openshadinglanguage'
+ 'jemalloc' 'libspnav' 'ptex' 'opensubdiv' 'openvdb' 'log4cplus' 'sdl2')
+makedepends=('cmake' 'boost' 'mesa' 'git' 'llvm35' 'gcc6')
+makedepends_x86_64=('cuda')
+optdepends=('cuda: cycles renderer cuda support')
+options=(!strip)
+source=("git://git.blender.org/blender-addons.git"
+ "git://git.blender.org/blender-addons-contrib.git"
+ "git://git.blender.org/blender-translations.git"
+ "git://git.blender.org/blender-dev-tools.git"
+ "git://git.blender.org/scons.git"
+ cuda9.patch)
+if [[ -n $_gittag ]]; then
+ source+=("${pkgname}-${pkgver}::git://git.blender.org/blender.git#tag=${_gittag}")
+elif [[ -n $_gitcommit ]]; then
+ source+=("${pkgname}-${pkgver}::git://git.blender.org/blender.git#commit=${_gitcommit}")
+fi
+md5sums=('SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ '88f47cac4cac2977f006c0ce22f84e53'
+ 'SKIP')
+
+prepare() {
+ cd "$srcdir/$pkgname-$pkgver"
+
+ git submodule init
+ git config submodule."release/scripts/addons".url ${srcdir}/blender-addons
+ git config submodule."release/scripts/addons_contrib".url ${srcdir}/blender-addons-contrib
+ git config submodule."release/datafiles/locale".url ${srcdir}/blender-translations
+ git config submodule."source/tools".url ${srcdir}/blender-dev-tools
+ git config submodule."scons".url ${srcdir}/scons
+ git submodule update
+
+ patch -Np1 < "${srcdir}"/cuda9.patch
+
+ # cuda 9.1 fixes
+ sed -i -e "s/sm_20;//" -e "s/sm_21;//" build_files/cmake/config/blender_release.cmake
+}
+
+build() {
+ cd "$srcdir/$pkgname-$pkgver"
+
+ [[ -d build ]] && rm -rf build
+ mkdir build && cd build
+
+ export CFLAGS="${CFLAGS} -DOPENVDB_3_ABI_COMPATIBLE"
+ export CXXFLAGS="${CXXFLAGS} -DOPENVDB_3_ABI_COMPATIBLE"
+ cmake -C../build_files/cmake/config/blender_release.cmake .. \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DWITH_INSTALL_PORTABLE=OFF \
+ -DWITH_PYTHON_INSTALL=OFF \
+ -DOPENIMAGEIO_ROOT_DIR=/usr \
+ -DWITH_LLVM=ON \
+ -DWITH_SYSTEM_OPENJPEG=ON \
+ -DWITH_GL_PROFILE_CORE=OFF \
+ -DWITH_GL_PROFILE_ES20=OFF \
+ -DLLVM_VERSION=3.6 \
+ -DLLVM_STATIC=ON \
+ -DWITH_CYCLES_CUDA_BINARIES=ON \
+ -DWITH_CYCLES_PTEX=OFF \
+ -DPYTHON_VERSION=3.6 \
+ -DPYTHON_LIBPATH=/usr/lib \
+ -DPYTHON_LIBRARY=python3.6m \
+ -DPYTHON_INCLUDE_DIRS=/usr/include/python3.6m
+ make
+
+ # PTEX is currently broken and experimental in blender anyway
+}
+
+package() {
+ cd "$srcdir/$pkgname-$pkgver/build"
+
+ make DESTDIR="${pkgdir}" install
+ install -Dm755 ../release/bin/blender-softwaregl "${pkgdir}/usr/bin/blender-softwaregl"
+ python -m compileall "${pkgdir}/usr/share/blender"
+ python -O -m compileall "${pkgdir}/usr/share/blender"
+}
Copied: blender/repos/community-staging-x86_64/cuda9.patch (from rev 276775, blender/trunk/cuda9.patch)
===================================================================
--- community-staging-x86_64/cuda9.patch (rev 0)
+++ community-staging-x86_64/cuda9.patch 2017-12-29 02:59:24 UTC (rev 276776)
@@ -0,0 +1,40 @@
+X-Git-Url: https://git.blender.org/gitweb/gitweb.cgi/blender.git/blobdiff_plain/22ecea9e38e708056262f3d98b0d0c6210da75cf..f55735e533601b559d53fd1e2c5297092e844345:/intern/cycles/kernel/CMakeLists.txt
+
+diff --git a/intern/cycles/kernel/CMakeLists.txt b/intern/cycles/kernel/CMakeLists.txt
+index b4ca16bdb48..b10dd05cb9b 100644
+--- a/intern/cycles/kernel/CMakeLists.txt
++++ b/intern/cycles/kernel/CMakeLists.txt
+@@ -321,7 +321,7 @@ if(WITH_CYCLES_CUDA_BINARIES)
+ set(CUDA_VERSION "${CUDA_VERSION_MAJOR}${CUDA_VERSION_MINOR}")
+
+ # warn for other versions
+- if(CUDA_VERSION MATCHES "80")
++ if(CUDA_VERSION MATCHES "80" OR CUDA_VERSION MATCHES "90")
+ else()
+ message(WARNING
+ "CUDA version ${CUDA_VERSION_MAJOR}.${CUDA_VERSION_MINOR} detected, "
+@@ -399,13 +399,17 @@ if(WITH_CYCLES_CUDA_BINARIES)
+ endmacro()
+
+ foreach(arch ${CYCLES_CUDA_BINARIES_ARCH})
+- # Compile regular kernel
+- CYCLES_CUDA_KERNEL_ADD(${arch} kernel "" "${cuda_sources}" FALSE)
+- CYCLES_CUDA_KERNEL_ADD(${arch} filter "" "${cuda_filter_sources}" FALSE)
+-
+- if(WITH_CYCLES_CUDA_SPLIT_KERNEL_BINARIES)
+- # Compile split kernel
+- CYCLES_CUDA_KERNEL_ADD(${arch} kernel_split "-D__SPLIT__" ${cuda_sources} FALSE)
++ if(CUDA_VERSION MATCHES "90" AND ${arch} MATCHES "sm_2.")
++ message(STATUS "CUDA binaries for ${arch} disabled, not supported by CUDA 9.")
++ else()
++ # Compile regular kernel
++ CYCLES_CUDA_KERNEL_ADD(${arch} kernel "" "${cuda_sources}" FALSE)
++ CYCLES_CUDA_KERNEL_ADD(${arch} filter "" "${cuda_filter_sources}" FALSE)
++
++ if(WITH_CYCLES_CUDA_SPLIT_KERNEL_BINARIES)
++ # Compile split kernel
++ CYCLES_CUDA_KERNEL_ADD(${arch} kernel_split "-D__SPLIT__" ${cuda_sources} FALSE)
++ endif()
+ endif()
+ endforeach()
+
More information about the arch-commits
mailing list